Moving headers and cell information

I have an extensive Excel file that was converted from a PDF. That is my problem because it does not put the information on the sheet the way I need it to so I can upload it to a database. Right now I have to type in all the information which is taking forever. Here is what I need. You would be saving me tons of hours if this can be done.

The file is attached: It needs to look like this:

StudentID (Which in this example is 169058) needs to have it's own column
Name, (In this example is Doe, John) needs to have it's own column
DOB
Description, own column
Teachers, own column
H1, H2, H3, H4, Fin, Avg Fin, all have it's own column.

I don't need the rest. As you will see in the attachment the headers are on the top and the information is inside the cells. I have 2500 students like this. So hopefully it would look like this:

StuID, Name, DOB, Description, Teacher, H1, H2, H3, H4, Fin, Avg Fin.

Can this be done?

Hello taichi56,

The macro below has been added to the attached workbook. The reformatted results are appear on "Sheet2". There is button to run the macro in cell "B1".

Sub ReformatData()

  Dim Data(1 To 10) As Variant
  Dim DstRng As Range
  Dim DstWks As Worksheet
  Dim N As Long, R As Long
  Dim RegExp As Object
  Dim SrcRng As Range
  Dim SrcWks As Worksheet
  
    Set SrcWks = Worksheets("Sheet1")
    Set DstWks = Worksheets("Sheet2")
    
      R = 1
      
      Set DstRng = DstWks.Range("A2")
        DstWks.UsedRange.Offset(1, 0).ClearContents
      
      Set RegExp = CreateObject("VBScript.RegExp")
        RegExp.IgnoreCase = True
    
        Do While SrcWks.Cells(R, "A") <> ""
          Set SrcRng = SrcWks.Cells(R, "A").CurrentRegion
            RegExp.Pattern = "(\d+)\s+(.+)"
              Data(1) = RegExp.Replace(SrcWks.Cells(R, "A"), "$1")
              Data(2) = RegExp.Replace(SrcWks.Cells(R, "A"), "$2")
            RegExp.Pattern = "DOB\:\s(.+)"
              Data(3) = RegExp.Replace(SrcWks.Cells(R, "C"), "$1")
                For R = R + 2 To SrcRng.Rows.Count + SrcRng.Row - 1
                  Data(4) = SrcWks.Cells(R, "C")
                  Data(5) = SrcWks.Cells(R, "F")
                  Data(6) = SrcWks.Cells(R, "H")
                  Data(7) = SrcWks.Cells(R, "I")
                  Data(8) = SrcWks.Cells(R, "J")
                  Data(9) = SrcWks.Cells(R, "K")
                  Data(10) = SrcWks.Cells(R, "L")
                    DstRng.Offset(N, 0).Resize(1, UBound(Data)).Value = Data
                  N = N + 1
                Next R
          R = R + 1
        Loop
        
End Sub

Man you guys are awesome. It is exactly what I need. I just need to add a column title Period and Avg Fin. I am working on it to see if I can get it, but probably not.

I figured it out. Thank you guys.