Run Time Error 91, Object Variable or With Block Variable not set

[undergraduate]

I have this macros below that keeps giving me a Run Time Error 91, Object Variable or With Block Variable not set prompt at the line that begins "Loop While". I was wondering if this can be fixed. This was a problem that arose from an existing thread, as its a new issue I am reposting. Thank You.

Dim c As Range, firstaddress As String, a As Long
Dim pSheet As Excel.Worksheet

For Each pSheet In ActiveWorkbook.Sheets
pSheet.Activate

With Columns(1)
  Set c = .Find("Investor", LookIn:=xlValues, LookAt:=xlWhole)
  If Not c Is Nothing Then
    firstaddress = c.Address
    Do
      a = a + 1
      If a > 1 Then c = "Holder"
      c.Offset(, 3) = "% of CSO"
      Range("C" & c.Row & ":C" & c.Row + 20).Value = Range("D" & c.Row & ":D" & c.Row + 20).Value
      Set c = .FindNext(c)
    Loop While Not c Is Nothing And c.Address <> firstaddress
   Range(firstaddress) = "Holder"
  Else
   
  End If

End With
Next pSheet

[StephenR]

Try changing that line to

Loop While c.Address <> firstaddress

[shg]

This line, which comes directly from Help, should NEVER be used:

Loop While Not c Is Nothing And c.Address <> firstaddress

If c is Nothing, then c.Address will error; and if c has an Address, it is not Nothing. (VBA always evaluates all arguments to a logical expression; if it paid attention to the And operator and quit after evaluating the first, it wouldn't be a problem)

If the search ultimately ends by finding the first entry again, then you should use

Loop While c.Address <> firstaddress

If it ends because you are destroying the found value, then use

Loop While Not c Is Nothing

If either could happen then

    If c is Nothing then Exit Do
Loop While c.Address <> firstaddress

[undergraduate]

Thank you it worked great, I used the following code:

 If c Is Nothing Then Exit Do
Loop While c.Address <> firstaddress
   Range(firstaddress) = "Holder"
  Else