Cumulative percent complete

zooom, welcome to the board.

To be honest, in my opinion/experience, you'd be better off storing the cumulative % in each cell and using Custom Formatting to hide those % < 10%

The reason for this is that in turn you avoid a lot of "double evaluation" and permit very straightforward/efficient calculations:

What I remain a little unclear on is the Seq# to be returned.

The first sequence is straightforward enough, however, where would the 2nd occurrence take place - my guess would be row 21 but what would be the sequence no. 6 or 7 ?
I guess I am unclear as to why the first entry is omitted altogether.

In terms of explaining basic thought process...

D2:
0

D3:
=IF($C3>=0.1,LOOKUP(9.99E+307,$D$1:$D2,$A$1:$A2),"")

C3:
=SUM($C2*($D2=""),$B3)
copied down

applying a Custom Format to C2:C256 of: [<0]"";[<0.1]"";0.00%

I very much suspect the above will need tweaking but we need to see a few more expected results (2nd seq, 3rd seq. etc...) to fully understand the minute detail of your requirements.

OK, so I think you're saying you're looking for a result for each seq # (1 to n), correct ?

Your latest sample raises a fundamental point as yet uncovered:

Q: what happens where you have multiple sequences achieving >= 10% at the same point ?
In your example SEQ 1 & 3 both occur at the same point.

If by the above you're implying delimited strings in both % Chg & Seq columns then I would say a VBA approach is something of a no-brainer
(a formula driven approach would be both convoluted and inefficient)

Taking the VBA route further... given the nature of the process I would err towards a Sub Routine (run as and when) as opposed to UDF [repetitive calls & overhead]
(you could add ChangeEvent to invoke the Sub Routine if necessary)

Using your most recent file as example below would be one possible route:

Sub Example()
    Dim vData As Variant, vRes() As Variant
    Dim lngSeq As Long, lngPct As Long
    Dim dblPct As Double
    With Sheets("Sheet3")
        With .Range(.Cells(2, "A"), .Cells(.Rows.Count, "A").End(xlUp)).Resize(, 2)
            vData = .Value
            With .Offset(, 2)
                .ClearContents
                ReDim vRes(1 To UBound(vData, 1), 1 To UBound(vData, 2))
                For lngSeq = LBound(vData, 1) To UBound(vData, 1) - 1 Step 1
                    dblPct = 0
                    For lngPct = lngSeq + 1 To UBound(vData, 1) Step 1
                        dblPct = dblPct + CDbl(vData(lngPct, 2))
                        If dblPct >= 0.1 Then
                            vRes(lngPct, 1) = vRes(lngPct, 1) & String(0 - (vRes(lngPct, 1) <> ""), ",") & Format(dblPct, "0.00%")
                            vRes(lngPct, 2) = vRes(lngPct, 2) & String(0 - (vRes(lngPct, 2) <> ""), ",") & vData(lngSeq, 1)
                            Exit For
                        End If
                    Next lngPct
                Next lngSeq
                .NumberFormat = "@"
                .Value = vRes
                .Columns.AutoFit
            End With
        End With
    End With
End Sub

the above would be stored in a standard module and run as and when (or invoked via Event as nec.)

I have taken the liberty of attaching your data with above code in place and with button present on sheet used to invoke the routine.
(you must ensure Macros are enabled of course)