Multi Condition Aggregation

I am trying to get a formula that will return a value based on two criteria from a different sheet.
I have tried array's, I have tried if/and, I am at a loss. Any help would be greatly appreciated.

Column1 Column2 Column3
MOM ---- 1 ---- 10
MOM ---- 2 ---- 15
DAD ---- 3 ---- 20
SON ---- 2 ---- 25
DGHT ---- 5 ---- 30
SON ---- 9 ---- 35
DAD ---- 3 ---- 40

All of this info is pasted on a sheet labeled "1"
on my other sheet (same workbook)
I would like to sum everything in column3 that is labeled DAD in column1 that is also >2 in column2
So in this case it would give me 60

Let me know if this is not clear. Thanks in advance for any help

Welcome to the Board

If as implied you're using XL2007 you can use SUMIFS

=SUMIFS('1'!$C:$C,'1'!$A:$A,"DAD",'1'!$B:$B,">2")

of course the tests can be replaced with cell references

Pending other requirements you might find a Pivot Table would also work for you (see link in sig. for general intro.)

Prior to XL2007 you would be looking at using SUMPRODUCT which would not accept entire column references and is inefficient - so best to keep precedent ranges as small as possible:

=SUMPRODUCT(('1'!$A$1:$A$100="DAD")*('1'!$B$1:$B$100>2),'1'!$C$1:$C$100)

on a final note please try to keep titles related to the specifics of the problem - I've modified for you on this occasion

thanks

Depends partly on the variety of items...

If there is nothing DAD* related that is not valid for aggregation then we might get away with wildcards within the SUMIFS:

=SUMIFS('1'!$C:$C,'1'!$A:$A,"DAD*",'1'!$B:$B,">2")

If, however, you have items like DADO which are to be excluded then you can use something like

=SUM(SUMIFS('1'!$C:$C,'1'!$A:$A,{"DAD","DAD1","DAD2"},'1'!$B:$B,">2"))

if your criteria (eg DAD,DAD1 etc) are "variables" (to be linked to cells) the above construct would not work given the inline array { } ... post back if nec.