Creating my own combobox class

I need to create my own combobox, complete with properties and events, that gets added on-the-fly. I'm trying to learn how to create class modules, but I'm having a difficult time finding an answer on how to do the following:

make a class module that displays an editable combobox on the screen.

Any pointers?
Thank you!

Based on your previous post, you don't want to do that. What you want is a class that handles the combobox events. For example:
Class called CComboHandler

Option Explicit

Public WithEvents Combo As MSForms.ComboBox

Private Sub Combo_Change()
    ' put whatever code you like in here
    MsgBox "You changed combo " & Combo.Name
End Sub

Then in sheet module of sheet with comboboxes on:

Option Explicit
' collection to hold the combobox handlers
Dim colHandlers As Collection
Public Sub HookCombos()
    Dim objHandler As CComboHandler
    Dim objOLE As OLEObject
    
    ' initialise the collection that holds the handlers
    Set colHandlers = New Collection
    
    For Each objOLE In Me.OLEObjects
        ' hook the combos
        If TypeName(objOLE.Object) = "ComboBox" Then
            ' create new handler instance
            Set objHandler = New CComboHandler
            ' assign the combobox to it
            Set objHandler.Combo = objOLE.Object
            ' now add to collection, so the handler doesn't go out of scope
            colHandlers.Add objHandler
        End If
    Next objOLE
End Sub

Private Sub Worksheet_Activate()
    HookCombos
End Sub

and you can also call the HookCombos sub from the Workbook_Open event:

Option Explicit

Private Sub Workbook_Open()
    Sheet1.HookCombos
End Sub

Demo file attached.

1. It would be fine in a module, but as it is sheet specific, I put it in the sheet.
2. The variables are declared and created in the HookCombos routine, which means that if you don't store them somewhere (an array would also work) they would lose their values when the routine ended.
3. Assigning an actual combo box to the class happens in the HookCombos routine. Remember that the class is really just a blueprint; you are simply saying that the class will have a combo box and you want to respond to its events.
4. It does assign the actual combo to the class' combo variable - that's why you can intercept the events for that actual combo box.

By declaring the variable WithEvents, you create what is known as an event sink, or event listener. Essentially it says that the class will 'listen' for the events of that control being raised. By adding the combo_change code, you specify what you want to happen when its Change event is raised.
If you are interested in this sort of thing, I would recommend getting hold of a good VBA book, such as the VBA Developers Handbook. You may also want to have a read of Chip's page here.

The objhandler objects can also be accessed by name or index, though here I did not specify a key when adding to the collection. There shouldn't really be any need to do this though - the sole purpose of the class is to handle events.
The combobox is already on the sheet when you assign it to the objhandler class so that question doesn't really apply. Since Combo is a reference to the actual on-sheet combobox, all the properties are available.
Unfortunately, activex controls are part of the vbproject so adding them or making design time changes, among other things, causes state loss and the collection goes out of scope and gets reset so you have to rerun the code. That's why I try to avoid controls on sheets generally and use Forms controls if possible if I really need controls on sheets.

Yes, you would have the same problem. It's nothing to do with the variable type, it's the fact it gets reset.

You haven't exactly given much to go on, so I'll have to guess. If your code is creating the comboboxes at the same time, then you will need to call the Hookcombos routine using Application.OnTime or your variable goes out of scope as soon as your code ends (since adding combos change the VBProject).