How to check and see if an application (exe) is already running

Hi There,

I need your help,

What would the vba code if I wanted to check and see if an application (ie. applicationA.exe) was already running?

I'd ideally like to have a MSGBOX popup and say "The application is already running" if the application is not running, load it.

Much thanks and appreciation for all your help.

Cheers,

Jay

Look into Word's VBA: collection Tasks.

Maybe this might help

So what about:

Sub snb()
  On Error Resume Next
  AppActivate "Microsoft Word"
  MsgBox "Word is " & IIf(Err.Number = 0, "already ", "not ") & "running"
End Sub

Hello

You may be interested in this method using the WMI instead of the API.

'Written: November 30, 2010
'Author: Leith Ross
'Summary: Count the instances of a running executable program

Sub ShowProgramCount()

  Dim Cnt As Long
  Dim colProcesses As Variant
  Dim Msg As String
  Dim objSWbemServices As Object
  Dim objProcess As Object
  Dim ProgramX As String
  Dim ThisComputer As String

    ProgramX = InputBox("Enter the name of the exectable file below.")
    If ProgramX = "" Then Exit Sub Else ProgramX = LCase(ProgramX)
    
    ThisComputer = "."
    
    Set objSWbemServices = GetObject("winmgmts:\\" & ThisComputer)
    Set colProcesses = objSWbemServices.InstancesOf("Win32_Process")
    
    For Each objProcess In colProcesses
       'Msg = Msg & Process.Name & vbCrLf
       If LCase(objProcess.Name) Like ProgramX Then
           Cnt = Cnt + 1
       End If
    Next objProcess

    MsgBox "Number of '" & ProgramX & "' Programs Open: " & Cnt

  Set objProcess = Nothing
  Set objSWbemServices = Nothing

End Sub