code to put borders around all used cells

I am using the code below to put borders around all cells in a specific worksheet however it isn't quite working as I need it to:

Range("a4").Select
    Range(Selection, Selection.End(xlDown)).Select
    Range(Selection, Selection.End(xlToRight)).Select
 
        With Selection.Borders
            .LineStyle = xlContinuous
            .Weight = xlThin
            .ColorIndex = xlAutomatic
        End With

If all the cells have something in then it works fine however if say the data goes say 10 rows down and 15 rows across and if only one cell in the last column had data in it then it doesn't work corrrectly.
so ideally what I need is to count the columns in the header row (row 4) which I can do, then count the number of filled cells in column A which again I can do then put cell borders around all the cells in the square that is formed which is where I am struggling to find the solution

This should do the trick

Sub SelectLastCellInInSheet()

    Dim Rws As Long, Col As Integer, r As Range, fRng As Range

    Set r = Range("A4")

    Rws = Cells.Find(What:="*", After:=r, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

    Col = Cells.Find(What:="*", After:=r, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column


    Set fRng = Range(Cells(4, 1), Cells(Rws, Col))    ' range A4 to last cell on sheet

    fRng.Select    'or whatever you want to do with the range

    With Selection.Borders
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
    End With
End Sub

Just a note, when turning on borders everywhere like this, it isn't necessary to actually "select" them, and you only need to turn on one parameter, the others will get turned on by default.

Dim LR as Long, LC as Long

LR = Range("A" & Rows.Count).End(xlUp).Row
LC = Cells(1, Columns.Count).End(xlToLeft).Column

Range("A4", Cells(LR, LC)).Borders.Weight = xlThin