protecting and unprotecting

At the moment I get an error when pressing the save as pdf button I've made. I believe this is because it is protected.

I've got a code that I would like to unprotect right before color change, and protect after pdf is made and color changed back. I've tried a few things, but I'm not really sure what I'm doing.

I've used before

.Unprotect

and

.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True, AllowFormattingRows:=True

But this doesn't work. Has this got something to do with the (Cancel As Boolean)?

Anyways:

Sub RDB_Sheet_Level_Names_To_PDF_And_Create_Mail()
    Dim FileName As String
    
    
    Sheets("Samlet").Range("C25:H26,G41:G42,G45:G55,E58:G58").Font.ColorIndex = 2
    FileName = Create_PDF_Sheet_Level_Names("addtopdf", "", True, False)
  
    If FileName <> "" Then
        RDB_Mail_PDF_Outlook FileName, "", "Emnet går her", _
                             "Se vedlegg" _
                           & vbNewLine & vbNewLine & "Mvh. ", False

    Else
        MsgBox "Not possible to create the PDF, possible reasons:" & vbNewLine & _
               "Microsoft Add-in is not installed" & vbNewLine & _
               "You Canceled the GetSaveAsFilename dialog" & vbNewLine & _
               "The path to Save the file in arg 2 is not correct" & vbNewLine & _
               "You didn't want to overwrite the existing PDF if it exist"
    End If
        Sheets("Samlet").Range("C25:H26,G41:G42,G45:G55,E58:G58").Font.ColorIndex = 3
    
End Sub

Any help would be very helpful. I'm learning slowly, but I seem to be hitting a lot of walls

Sub RDB_Sheet_Level_Names_To_PDF_And_Create_Mail()
    Dim FileName As String

    With Sheets("Samlet")
    
        .Unprotect
        .Range("C25:H26,G41:G42,G45:G55,E58:G58").Font.ColorIndex = 2
        FileName = Create_PDF_Sheet_Level_Names("addtopdf", "", True, False)
      
        If FileName <> "" Then
            RDB_Mail_PDF_Outlook FileName, "", "Emnet går her", _
                                 "Se vedlegg" _
                               & vbNewLine & vbNewLine & "Mvh. ", False
    
        Else
            MsgBox "Not possible to create the PDF, possible reasons:" & vbNewLine & _
                   "Microsoft Add-in is not installed" & vbNewLine & _
                   "You Canceled the GetSaveAsFilename dialog" & vbNewLine & _
                   "The path to Save the file in arg 2 is not correct" & vbNewLine & _
                   "You didn't want to overwrite the existing PDF if it exist"
        End If
        
        .Range("C25:H26,G41:G42,G45:G55,E58:G58").Font.ColorIndex = 3
        .Protect DrawingObjects:=True, Contents:=True, Scenarios:=True, AllowFormattingRows:=True
    End With
End Sub