Time macro

[kamalthakur]

Hi I need a help to create a macro to calculate start time and end time

If I enter any value in Cell A1, B1 should populate time and If I enter value in C1,D1 should populate end time

Only challenge what I am facing is If I type something in Cell A1, B1 populates the time but if i delete the content in A1 It should delete the time in B1

[Leith Ross]

Hello kamalthakur,

Please post any VBA code or formulas you have. It will make it easier to propose a useful solution.

[kamalthakur]

Private Sub Worksheet_Change(ByVal Target As Range)
        If Target.Columns.Column = Columns("a").Column _
        Or _
       Target.Columns.Column = Columns("c").Column Then
       Target.Offset(, 1).Value = Now()
    End If
End Sub.

[Leith Ross]

Hello kamalthakur,

Here is the working macro code.

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Cells.Count > 1 Or Target.Column > 2 Then Exit Sub
    
      Application.EnableEvents = False
        Select Case Target.Column
          Case 1
            If Target.Value = "" Then
               Target.Offset(0, 1).Value = ""
            Else
               Target.Offset(0, 1).Value = Now()
            End If
          Case 2
            If Target.Value = "" Then
               Target.Offset(0, -1).Value = ""
            Else
               Target.Offset(0, -1).Value = Now()
            End If
        End Select
      Application.EnableEvents = True
    
End Sub

[DonkeyOte]

If I've understood:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngI As Range, rngC As Range
    On Error GoTo ExitPoint
    Application.EnableEvents = False
    Set rngI = Intersect(Target, Union(Columns(1), Columns(3)))
    If Not rngI Is Nothing Then
        For Each rngC In rngI.Cells
            rngC.Offset(, 1).Value = IIf(rngC.Value = "", "", Now)
        Next rngC
    End If
ExitPoint:
    Set rngI = Nothing
    Application.EnableEvents = True
End Sub