how to retrieve a file

retrieve.JPG

From the picture we can see a combobox and a button. What I need to do now is that once I select a combobox and hit the button. I should able to retrieve a file by the name that is exactly same as the combobox name. For e.g. when I select apple combobox, I should able to select a file name that must be apple.txt. And the user has the freedom to choose the location of the file (e.g. the file can be in C drive or D drive or any other folder). I managed to create these codes,

Private Sub CommandButton1_Click()

On Error GoTo ErrorHandler

If ComboBox1.Text = "apple" Then
    myFile = Application.GetOpenFilename("Text Files,*.txt")
 Workbooks.OpenText Filename:= _
        myFile, Origin _
        :=xlWindows, StartRow:=1, DataType:=xlFixedWidth, FieldInfo:=Array(Array _
        (4, 1), Array(10, 1), Array(26, 1), Array(27, 1), Array(50, 1), Array(58, 1)), _
        TrailingMinusNumbers:=True
    ActiveSheet.Move After:=Workbooks("retriveFile.xls").Sheets(1)
    ActiveWindow.WindowState = xlMaximized
    Exit Sub
End If
ErrorHandler:
    MsgBox "Plese select a file", vbInformation, "unable to continue" '& Err.Number & vbCrLf & vbCrLf & Err.Description
End Sub

From this code, the user can choose the file from any location. But at the same time he can also any .txt file, which what I want to avoid.

Important:
* File I want to retrieve is in .txt format
* the user must have full freedom in choosing the file location
* But he can only select a .txt file name that is exactly same as to the combobox he select (e.g. if he select apple for the combobox then, he can only open a file name that goes by apple.txt)

Hello darkhorse4321,

Where is this macro located? Is the macro code for the CommandButton? Please post all the code.

Hello darkhorse4321,

Here is the updated version of your macro.

Private Sub CommandButton1_Click()

  Dim Filename As String
  Dim I As Integer
  Dim myFile As Variant
  Dim myFileName As String
    
      If ComboBox1.ListIndex = -1 Then Exit Sub
      Filename = ComboBox1.Value
    
       myFile = Application.GetOpenFilename("Text Files,*.txt")
       
      'Check if Cancel was clicked
       If myFile = False Then Exit Sub
       
      'Extract the file name from the path
       myFileName = Right(myFile, Len(myFile) - InStrRev(myFile, "\"))
       
      'Check that the file names match. This is not case sensitive
       If StrComp(myFileName, Filename, vbTextCompare) <> 0 Then
          MsgBox "Not a Valid File.", vbInformation, "unable to continue"
          Exit Sub
       End If
       
       Workbooks.OpenText Filename:=myFile, _
                          Origin:=xlWindows, _
                          StartRow:=1, _
                          DataType:=xlFixedWidth, _
                          FieldInfo:=Array(Array(4, 1), Array(10, 1), _
                                           Array(26, 1), Array(27, 1), _
                                           Array(50, 1), Array(58, 1)), _
                          TrailingMinusNumbers:=True
      ActiveSheet.Move After:=Workbooks("retriveFile.xls").Sheets(1)
      ActiveWindow.WindowState = xlMaximized
        
End Sub