code for hiding taskbar

Why not just use display full screen

Option Explicit

Sub ToggleFullScreen()
Application.DisplayFullScreen = Not Application.DisplayFullScreen
End Sub

There's an example in this earlier post

I use Windows 7 too. So far I have not found an elegant method of hiding the Taskbar + the Start Button in this OS (and believe me I have tried). I even used VS Spy utility to try to 'Switch off' the Button according to Class & Caption but to no avail.

So, I use the following Code to toggle the Taskbar Status. By forcing Excel FullScreen it will then occupy the entire Desktop Window.

Option Explicit

' d_taskbar, turns the system taskbar on or off :: FullScreen Excel AddIn

' SHAppBarMessage
Private Declare Function _
 SHAppBarMessage Lib "shell32.dll" _
 (ByVal dwMessage As Long, _
  ByRef pData As APPBARDATA) As Long

' local const
Private Const ABS_AUTOHIDE As Long = &H1
Private Const ABM_GETTASKBARPOS As Long = &H5
Private Const ABM_GETSTATE As Long = &H4
Private Const ABM_SETSTATE As Long = &HA
Private Const ABM_SETAUTOHIDEBAR As Long = &H8

' local type
Private Type RECT
 left As Long
 Top As Long
 right As Long
 Bottom As Long
End Type

Private Type APPBARDATA
 cbSize As Long
 hWnd As Long
 uCallbackMessage As Long
 uEdge As Long
 rc As RECT
 lParam As Long
End Type

' local vars
Dim abd As APPBARDATA
Dim abd_retval, _
    abd_setval As Long

' AutoHideTaskBar :: sets the appdardata, lParam struct to autohide the system taskbar
Public Sub HideTaskbar()
On Error GoTo TaskbarErrorHandler
 Application.EnableCancelKey = xlErrorHandler
  abd_retval = _
   SHAppBarMessage(ABM_GETSTATE, abd)
  abd.lParam = _
   abd_retval Or ABS_AUTOHIDE
  abd_setval = _
   SHAppBarMessage(ABM_SETSTATE, abd)
  Exit Sub
TaskbarErrorHandler:
 On Error Resume Next
End Sub
' /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
' /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

' RestoreTaskBar :: restores the autohide system taskbar to a normal state
Public Sub UnhideTaskbar()
On Error GoTo TaskbarErrorHandler
 Application.EnableCancelKey = xlErrorHandler
  abd_retval = _
   SHAppBarMessage(ABM_GETSTATE, abd)
  abd.lParam = _
   abd_retval And Not ABS_AUTOHIDE
  abd_setval = _
   SHAppBarMessage(ABM_SETSTATE, abd)
  Exit Sub
TaskbarErrorHandler:
 On Error Resume Next
End Sub
' /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
' /////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

The Error Handler Code is Optional.

I have written a FullScreen Add-In at:
http://www.kubiszyn.co.uk

I am also working on a Free 2003 Add-In which will run along the same lines by toggling the Taskbar Status. When this is finalised I will Post up some Code for re-styling the Excel App + Hiding the Taskbar. Mark Kubiszyn.

Hello ditisFloris,

Copy this code into a separate VBA module in your workbook. Call the macro ShowFullScreen in your code. Be sure to call ShowNormalScreen before you close the workbook.

'Written: January 19, 2011
'Author:  Leith Ross
'Summary: Macros to hide and show the Windows Taskbar. Works with Windows '95 - 2003.
'         Does not work with Vista. There are two additional macros to set the display
'         to full screen and restore the display to normal.

Private Declare Function FindWindow _
  Lib "User32.dll" Alias "FindWindowA" _
    (ByVal lpClassName As String, _
     ByVal lpWindowName As String) As Long
 
Private Declare Function SetWindowPos _
  Lib "User32.dll" _
    (ByVal hWnd As Long, _
     ByVal hWndInsertAfter As Long, _
     ByVal X As Long, _
     ByVal Y As Long, _
     ByVal cx As Long, _
     ByVal cy As Long, _
     ByVal uFlags As Long) As Long
 
Const HWND_TOP As Long = &H0&
Const SWP_HIDEWINDOW As Long = &H80&
Const SWP_SHOWWINDOW As Long = &H40&

Sub HideTaskbar()
  Dim Taskbar As Long
    Taskbar = FindWindow("Shell_traywnd", "")
    Call SetWindowPos(Taskbar, HWND_TOP, 0, 0, 0, 0, SWP_HIDEWINDOW)
End Sub
 
Sub UnhideTaskbar()
  Dim Taskbar As Long
    Taskbar = FindWindow("Shell_traywnd", "")
    Call SetWindowPos(Taskbar, HWND_TOP, 0, 0, 0, 0, SWP_SHOWWINDOW)
End Sub

Sub ShowFullScreen()

      HideTaskbar
      
        With Application
          .DisplayFullScreen = True
          .CommandBars("Worksheet Menu Bar").Enabled = False
        End With
        
        With ActiveWindow
          .DisplayHeadings = False
          .DisplayHorizontalScrollBar = True
          .DisplayVerticalScrollBar = True
          .DisplayWorkbookTabs = True
       End With
      
End Sub

Sub ShowNormalScreen()

      UnhideTaskbar
      
        With Application
          .DisplayFullScreen = False
          .CommandBars("Worksheet Menu Bar").Enabled = True
        End With
        
        With ActiveWindow
          .DisplayHeadings = True
          .DisplayHorizontalScrollBar = True
          .DisplayVerticalScrollBar = True
          .DisplayWorkbookTabs = True
       End With

End Sub