insert a photo (any file type), resize it, and place it in a specific location.

[jaganath]

To date i have the following code written.

Sub InsertPhoto()
Range("E7").Select
ActiveSheet.Pictures.Insert( _
Application.GetOpenFilename( _
"JPG picture files (*.jpg),*.jpg", , "Select the picture")).Select
Selection.ShapeRange.LockAspectRatio = msoTrue
    Selection.ShapeRange.Height = 800
    Selection.ShapeRange.Width = 343
End Sub

With the code shown above I am only able to post JPeg images and I get a run time error when I attempt to cancel out of the search window (when selecting a file to insert).

Can someone tell me what I need to do to allow my searches to cancel and allow me to search for and resize all file types and not simply JPeg images.

Thanks.

[JBeaucaire]

Try this:

Option Explicit

Sub InsertPhoto()
Dim fName As String

Range("E7").Select
fName = Application.GetOpenFilename("Picture files (*.jpg;*.gif;*.bmp), *.jpgs;*.gif;*.bmp", , _
            "Select the picture")
If fName = "False" Then Exit Sub

ActiveSheet.Pictures.Insert(fName).Select
                    
Selection.ShapeRange.LockAspectRatio = msoTrue
    Selection.ShapeRange.Height = 800
    Selection.ShapeRange.Width = 343

End Sub

[jaganath]

perfect! thanks.

[ditisFloris]

it places the picture, it resize it, but it don't place it in a specific location.. (in this place not in "E7")
at least not for me. it places it in the left top corner, about 2 cm away from the sides

how can you directly place a picture in the cell you want?

Edit:
I searched further on this forum and found the answer. for those who need this code, i'll post it with a small addition so it will save you search time.

Sub InsertPhoto()
Dim fName As String

Range("E7").Select
fName = Application.GetOpenFilename("Picture files (*.jpg;*.gif;*.bmp), *.jpgs;*.gif;*.bmp", , _
            "Select the picture")
If fName = "False" Then Exit Sub

ActiveSheet.Pictures.Insert(fName).Select
     With Selection.ShapeRange
        .LockAspectRatio = msoTrue
        .Top = Range("E7").Top
        .Left = Range("E7").Left
        .Height = Range("E7").Height
        .Width = Range("E7").Width
    End With                 

End Sub

(this probably only make a difference on excel 2007