Delete if in list

[Hjahren]

Hello!

I want to define a list, and delete row if the the column contains a value in the list:

Something like this

Sub deleteIFinlist

Dim List
99998
99984
99994

For rwNum = lastRow To 1 Step -1
   If Cells(rwNum, "h") = List or then
   Cells(rwNum, "h").EntireRow.Delete
End If 
Next


End sub

[blane245]

Here's something that may be close to what you want:

Sub deleteIFinlist()

    Dim List() As Variant    ' the list of values to be deleted
    List = Array(99998, 99984, 99994)

    ' find the last row of the used range
    Dim lastRow As Long
    Dim theRange As Range
    Set theRange = Sheet1.UsedRange
    lastRow = theRange.Rows(theRange.Rows.Count).Row



    ' loop through all of the rows backwards
    Dim rwNum As Long
    For rwNum = lastRow To 1 Step -1

        ' search for the value in column H of this row
        Dim i As Long
        For i = LBound(List) To UBound(List)
            If (Sheet1.Cells(rwNum, 8).Value = List(i)) Then

                ' delete the row
                Sheet1.Rows(rwNum).EntireRow.Delete
                Exit For
            End If
        Next i
    Next rwNum

End Sub