How to Use Word as Email Editor in Excel 2007

Hello nobleprince,

I am not sure I follow your post. You state that you can only send emails in plain text. You then ask about about using Word as email editor. What are you trying to do? Do you want to change the email to Rich Text Format or HTML and resend it?

See Ron de Bruin's Excel email code, you should find how to send as HTML

Hello noblleprince,

Here is macro that will send a specified range in HTML format within the body of the email. If this isn't what you need, let me know and I will put something together for you that does what you need.

'Written: September 22, 2008
'Author:  Leith Ross
'Summary: Send a specfied worksheet range in the body of an Outlook email
'         in HTML format.


Sub EmailRangeInHTML(ByVal Recipient As String, ByVal Subject As String, Optional Range_To_Send As Variant)

  Dim FSO As Object
  Dim HTMLcode As String
  Dim HTMLfile As Object
  Dim MyApp As Boolean
  Dim olApp As Object
  Dim Rng As Range
  Dim TempFile As String
  Dim Wks As Worksheet

  Const ForReading As Long = 1
  Const olMailItem = 0
  Const olFormatHTML = 2
  Const UseDefault As Long = -2
    
     If IsMissing(Range_To_Send) Then
       Set Rng = Selection
     Else
       Select Case TypeName(Range_To_Send)
         Case Is = "Range"
           Set Rng = Range_To_Send
         Case Is = "String"
           Set Rng = Evaluate(Range_To_Send)
         Case Else
           MsgBox "Your Selection is Not a Valid Range."
           GoTo CleanUp
       End Select
     End If
     
     Set Wks = Rng.Parent
     TempFile = Environ("Temp") & "\Email.htm"
     
     'Start Outlook
      Set olApp = CreateObject("Outlook.Application")
      
         'Convert the Message worksheet into HTML
          With ActiveWorkbook.PublishObjects.Add( _
            SourceType:=xlSourceRange, _
            FileName:=TempFile, _
            Sheet:=Wks.Name, _
            Source:=Rng.Address, _
            HtmlType:=xlHtmlStatic)
           .Publish (True)
          End With
       
         'Read the HTML file back as a string
          Set FSO = CreateObject("Scripting.FileSystemObject")
          
          Set HTMLfile = FSO.GetFile(TempFile).OpenAsTextStream(ForReading, UseDefault)
            HTMLcode = HTMLfile.ReadAll
          HTMLfile.Close
          
         'Clean up the HTML code
          HTMLcode = Replace(HTMLcode, "align=center x:publishsource=", _
                             "align=left x:publishsource=")
                      
         'Compose the email and send it
          Set olEmail = olApp.CreateItem(olMailItem)
            With olEmail
              .To = Recipient
              .Subject = Subject
              .BodyFormat = olFormatHTML
              .HTMLBody = HTMLcode
              .Send
            End With
            
CleanUp:
  'Exit Outlook
   olApp.Quit
  'Delete the Temp File
   If Dir(TempFile) <> "" Then Kill TempFile
  'Delete the Publish Object
   With ActiveWorkbook.PublishObjects
     If .Count <> 0 Then .Item(.Count).Delete
   End With
   
  'Free memory resources
   Set olApp = Nothing
   Set olEmail = Nothing
   Set FSO = Nothing

End Sub

Example of Using the MAcro

Sub EmailMyself()

 'Insert your email address in place of your_name@youremail.com
  EmailRangeInHTML "your_name@youremail.com", "Sending Range in HTML test", Worksheets("Sheet1").Range("A1:E10")
  
End Sub

Hi nobleprince

Assuming this issue is related to what we've been working on, the code Ive provided will send your emails in either HTML or Rich Text (at least it does in my tests). Check your settings in Outlook (New->Options->Format). Using the same procedures we've been working on, I've sent myself emails in HTML text.

See if this works for you.

John