Send Mail Macro

Hello there,

I would like to create a macro for my workbook which sends a mail message to addresses in Column C (range C2:C100) when the value in column F (range f2:f100) reads "Yes". Does such a thing exist?

Your help is graciously appreciated.

Jordan

I believe you need to be more specific. What are you wanting to send? One of the cells? The worksheet? The workbook? Just a pre-filled email?

This may get you started

Private Sub Worksheet_Change(ByVal Target As Range)
    ' If the value a cell within range F2 to F100 is changed to Yes
    ' then send an email alert
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sBody As String
    Dim sTo As String
    If Not Intersect(Target, Range("f2:f100")) Is Nothing Then
        With Target
            If .Value = "Yes" And .Count = 1 Then
                sBody = "The status of the record in row " & .Row & _
                        " has been updated to ""Yes"" by " & Environ("username")
                sTo = Cells(.Row, "C").Value
                Set OutApp = CreateObject("Outlook.Application")
                OutApp.Session.Logon
                Set OutMail = OutApp.CreateItem(0)
                On Error Resume Next
                With OutMail
                    .to = sTo
                    .Subject = "Status Update"
                    .Body = sBody
                    .display ' to send automatically change .display to .send
                End With
                On Error GoTo 0
                Set OutMail = Nothing
                Set OutApp = Nothing
            End If
        End With
    End If
End Sub