Macro-Inserting Rows

[Brittney10]

So i have some borrowed code here. Instead if it just inserting a new line/lines based on the active cell (which could be any random spot the user unknowingly may click on), I want the user to know what's going on and be prompted to select where he/sher wants to insert the new line. Perhaps a message box that says "Select where you wish to insert the new line/lines." Thanks for the help in advance!


Sub InsertRow()

Dim Rng, n As Long, k As Long
Application.ScreenUpdating = False
Rng = InputBox("Enter number of rows required.")
If Rng = "" Then Exit Sub
Range(ActiveCell, ActiveCell.Offset(Val(Rng) - 1, 0)).EntireRow.Insert
k = ActiveCell.Offset(-1, 0).Row
n = Cells(k, 256).End(xlToLeft).Column
Range(Cells(k, 1), Cells(k + Val(Rng), n)).FillDown

End Sub

[JBeaucaire]

Maybe like so:

Option Explicit

Sub CopyRowMultipleTimes()
Dim iRow    As Range
Dim AddRows As Long
Do
    Set iRow = Application.InputBox("Choose a single row to copy.", Type:=8)
    If iRow.Rows.Count = 1 Then
        Exit Do
    Else
        If MsgBox("You must select only one row, abort?", vbYesNo) = vbYes _
            Then Exit Sub
    End If
Loop

Do
    AddRows = Application.InputBox("How many rows to insert?", Type:=2)
    If AddRows < 1 Then
        If MsgBox("Abort?", vbYesNo) = vbYes Then Exit Sub
    Else
        Exit Do
    End If
Loop

iRow.Copy
iRow.Offset(1).Resize(AddRows).Insert
Application.CutCopyMode = False

Set iRow = Nothing
End Sub

[Brittney10]

It's works!!!! You're so AWESOME! Can I also get it to when they hit cancel it doesn't give me a debug error?

[Brittney10]

When it cancels the first message box....i.e the rows to select