Insert multiple Photos MACRO

Hello all,
I use the following macro (found it in a forum) below to insert photos in Column A of my worksheet and it works great!
But I need a MACRO that will load hundreds of photos all down Column A. what code needs to be added in order for that to work? Im just a novice and have been searching for a Macro I can copy that will let me load hundreds of photos automatically. Thank you!!

Sub InsertPicture()
Dim sPicture As String, pic As Picture
 
sPicture = Application.GetOpenFilename _
    ("Pictures (*.gif; *.jpg; *.bmp; *.tif), *.gif; *.jpg; *.bmp; *.tif", _
     , "Select Picture to Import")
 
If sPicture = "False" Then Exit Sub
 
Set pic = ActiveSheet.Pictures.Insert(sPicture)
With pic
    .ShapeRange.LockAspectRatio = msoFalse
    .Height = ActiveCell.Height
    .Width = ActiveCell.Width
    .Top = ActiveCell.Top
    .Left = ActiveCell.Left
    .Placement = xlMoveAndSize
End With
 
Set pic = Nothing
 
End Sub

Welcome to the forum.

Please take a few minutes to read the forum rules, and then edit your post to add CODE tags.

So how do you want to select these hundreds of pictures to insert?

I have them all in one folder in the My pictures folder in my c drive and would like to insert them starting from Cell A2 and just get loaded all down column A (my photo column). The images are already compressed for document viewing. The number of images I insert will vary for each photo inventory document I need to create. Hope that's helpful.

Sub yazl()
    InsertAllPix Range("A1"), _
                "C:\Documents and Settings\yazl\My Pictures\My Directory", _
                "*.jpg"
End Sub

Sub InsertAllPix(r As Range, ByVal sDir As String, sFilt As String)
    Dim sPic As String
    Dim iRow As Long
    
    If Right(sDir, 1) <> "\" Then sDir = sDir & "\"
    sPic = Dir(sDir & sFilt)
    
    Do While Len(sPic)
        iRow = iRow + 1
        With ActiveSheet.Pictures.Insert(sDir & sPic)
            .ShapeRange.LockAspectRatio = msoFalse
            .Height = r(iRow, 1).Height
            .Width = r(iRow, 1).Width
            .Top = r(iRow, 1).Top
            .Left = r(iRow, 1).Left
            .Placement = xlMoveAndSize
        End With
        sPic = Dir
    Loop
End Sub

Racquel Casinsinan,

Unfortunately you need to post your question in a new thread, it's against the forum rules to post a question in the thread of another user. If you create your own thread, any advice will be tailored to your situation so you should include a description of what you've done and are trying to do. Also, if you feel that this thread is particularly relevant to what you are trying to do, you can surely include a link to it in your new thread.