Insert multiple Photos MACRO

I have them all in one folder in the My pictures folder in my c drive and would like to insert them starting from Cell A2 and just get loaded all down column A (my photo column). The images are already compressed for document viewing. The number of images I insert will vary for each photo inventory document I need to create. Hope that's helpful.

Sub yazl()
    InsertAllPix Range("A1"), _
                "C:\Documents and Settings\yazl\My Pictures\My Directory", _
                "*.jpg"
End Sub

Sub InsertAllPix(r As Range, ByVal sDir As String, sFilt As String)
    Dim sPic As String
    Dim iRow As Long
    
    If Right(sDir, 1) <> "\" Then sDir = sDir & "\"
    sPic = Dir(sDir & sFilt)
    
    Do While Len(sPic)
        iRow = iRow + 1
        With ActiveSheet.Pictures.Insert(sDir & sPic)
            .ShapeRange.LockAspectRatio = msoFalse
            .Height = r(iRow, 1).Height
            .Width = r(iRow, 1).Width
            .Top = r(iRow, 1).Top
            .Left = r(iRow, 1).Left
            .Placement = xlMoveAndSize
        End With
        sPic = Dir
    Loop
End Sub

Thank you for this code Shg.
IT WORKED!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! I cant thank you enough! at first it didnt work but then I double checked my path and made some changes and it works! Im so relieved that I wont have to drag and drop 1000 photos one by one!

If I may inquire further, is there any way to retain the original photo file name when it gets inserted into the worksheet so that it can be read in the Name Box above column A.
And finally I am wondering how the code you wrote for me could be slightly adjusted so that the images are just a little smaller than the cells the are in. As they are now they overlap the cells and thus will not move when I do a custom sort of my worksheet.

Thank you again so much for your assistance I appreciate it so much!