Copy rows from one sheet to another based on 2 conditions

I am looking to copy data from one sheet to another based on the value in a to columns. If column "N" contains "WDWO" and if "I" is less than "600" then I need to move three fields in that row to a different sheet. the fields that need to be moved are in columns a, e, j. I have attached a sample of the sheets before and after. My original sheet is sheet 1 and my filtered sheet is sheet 2. As always thanks ahead for the help and it is much appreciated! And I need this in a macro so I can automate this process because I have to do this with 8 different sheets.

Option Explicit
Sub test()
    Dim Duration    As Range, _
        Codes       As Range, _
        TestCode    As Range, _
        Destination As Worksheet, _
        Source      As Worksheet, _
        LastRow     As Long, _
        NextRow     As Long, _
        DataVals    As Variant, _
        DestRange   As String
        
    Const WDWO      As String = "WDWO"
    Const TESTVAL   As Long = 600
    
    Set Source = Sheets("Sheet1")
    Set Destination = Sheets("sheet3")
    
    'put in the destination sheet headers
    Destination.Range("A1:C1").Value = Array("Real Time", "Station #", "Duration")
    
    'get the last source row with data
    LastRow = Source.Cells(Rows.Count, 1).End(xlUp).Row
    
    'initialize the ranges to operate on
    Set Duration = Source.Range("I2:I" & LastRow)
    Set Codes = Source.Range("N2:N" & LastRow)
    
    'test each code column cell against the test parms, if true then copy to destination sheet
    For Each TestCode In Codes
        If TestCode.Value = WDWO And TestCode.Offset(0, -5).Value < TESTVAL Then
            
            'move the dest row pointer down one row
            NextRow = Destination.Cells(Rows.Count, 1).End(xlUp).Row + 1
            DestRange = "A" & NextRow & ":C" & NextRow
            
            'copy stuff to holder
            With TestCode
                DataVals = Array(.Offset(0, -13).Value, .Offset(0, -9).Value, .Offset(0, -4).Value)
            End With
            
            'paste stuff from holder
            Destination.Range(DestRange) = DataVals
        End If
    Next TestCode
End Sub

How is your actual sheet different from the sample? May need a bigger sample including data that you think is causing the problems.