Copy multiple sheets to new workbook

I would like to copy sheet "PPR", "Consolidation", "Pivot" to a new workbook and prompt user to input a name and then save this new workbook to the same Dir

My idea is to have a button on the Main sheet for user to click - in turn will make a copy of the 3 existing templates above into a new workbook, execute the codes and save.

I found this piece of code from ms, but it can only move to an existing wb.

I hope you can help me with this function.

Thank you,

Sub Mover3()
   Dim BkName As String
   Dim NumSht As Integer
   Dim BegSht As Integer

   'Starts with second sheet - replace with index number of starting sheet.
   BegSht = 2
   'Moves two sheets - replace with number of sheets to move.
   NumSht = 3
   BkName = ActiveWorkbook.Name
    
    For x = 1 To NumSht
      'Moves second sheet in source to front of designated workbook.
      Workbooks(BkName).Sheets(BegSht).Move _
         Before:=Workbooks("Test.xls").Sheets(1)
         'In each loop, the next sheet in line becomes indexed as number 2.
      'Replace Test.xls with the full name of the target workbook you want.
    Next
End Sub

I think I have the prompt for name & save on the same location

    Dim filNAME As String
    filNAME = InputBox("Please Enter Prompt Pay Month")
    File = ThisWorkbook.Path & "\Report " & filNAME
    ActiveWorkbook.SaveAs Filename:=File, FileFormat:=xlOpenXMLWorkbook, _
            CreateBackup:=False
    Application.DisplayAlerts = True
            MsgBox ("File Saved As " & ThisWorkbook.Path & "\Report " & _
    filNAME & ".xls. OK To Continue!")

I can't test the SaveAs command you used, I get an error on that xlOpenXMLWorkbook, but if it works for you...

Option Explicit

Sub CopyToNewWorkbook()
Dim fName As String
Dim sht As Worksheet
Application.ScreenUpdating = False

fName = Application.InputBox("Please Enter Prompt Pay Month", "File Name", Type:=2)
If fName = "False" Then Exit Sub
fName = ThisWorkbook.Path & Application.PathSeparator & "Report " & fName

    For Each sht In Sheets(Array("PPR Summary", "Consolidate", "Pivot"))
        sht.Select False
    Next sht

    ActiveWindow.SelectedSheets.Copy
    ActiveWorkbook.SaveAs Filename:=fName, FileFormat:=xlOpenXMLWorkbook
    ActiveWorkbook.Close False
    MsgBox "File saved as " & fName & ".xls" & vbLf & vbLf & "OK to continue!"
    
Application.ScreenUpdating = True
End Sub