File:Create list

post a workbook with sample data and expected outcome

well with functions you have alot of work to do.
insert a new column for every aircraft to dount the "x "s ive done col H on a119master
you can then index match using the formula given on sheet n108ag
note rather than insert a column you could use another sheet to do the counting and use that.
see missionmaster2

The programming option you can try. The macro will go by each sheet name and look for a matching column of data on the A119 sheet. If one is found, it will put the items marked into the Removable Equipment section of that sheet. The section can be in a different spot on each sheet, it will still work.

You can "mark" items with anything, not just "X", any entry at all will cause it to transfer to that sheet.

Any sheets without a matching column of data will be noted for you by the macro so you can check it later. Just press the button anytime you want to update the other sheets.

Option Explicit

Sub ParseRemovableEquipment()
'Jerry Beaucaire   5/2/2010
Dim ws As Worksheet, wsA119 As Worksheet
Dim MRE As Range    'Mission Removable Equipment
Dim Col As Long     'column on A119 to filter
Dim LR  As Long     'last row of data

Application.ScreenUpdating = False
Set wsA119 = Sheets("A119 MASTER")
wsA119.Range("2:2").AutoFilter

For Each ws In Worksheets
    If ws.Name <> wsA119.Name Then
    'Find the MRE and remove current entries
        Set MRE = ws.Cells.Find(What:="Mission Removable Equipment", _
            After:=ActiveCell, LookIn:=xlValues, LookAt:=xlWhole, _
            SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
        ws.Range("A" & MRE.Row + 1, "E" & Rows.Count).ClearContents
    'Filter A119 for new data
        On Error GoTo ErrorHandler
        Col = wsA119.Rows(2).Find(What:=ws.Name, _
            After:=wsA119.[A2], LookIn:=xlValues, LookAt:=xlWhole, _
            SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False).Column
        On Error GoTo 0
        wsA119.Range("2:2").AutoFilter Field:=Col, Criteria1:="<>"
    'Test if any items to copy, copy them if so, all at once
        LR = wsA119.Cells(wsA119.Rows.Count, Col).End(xlUp).Row
        If LR > 2 Then
            wsA119.Range("A3:E" & LR).Copy
            ws.Range("A" & MRE.Row + 1).PasteSpecial xlPasteValuesAndNumberFormats
        End If
Next1:
        wsA119.Range("2:2").AutoFilter Field:=Col
    End If
Next ws

wsA119.AutoFilterMode = False
Application.ScreenUpdating = True
Beep
Exit Sub

ErrorHandler:
    MsgBox "No column of data was found matching " & ws.Name & "," _
        & vbLf & "make a note and correct for next time if needed." _
        & vbLf & vbLf & "Continuing with next aircraft type..."
    On Error GoTo 0
    GoTo Next1
End Sub

Yes, you just need to enable macros on protected sheets. There a many ways to do that.

Are you going to protect each sheet with the same settings and the same password? If so, turn on the macro recorder and let it record you protecting one sheet with all the settings the way you want. Post the resulting code here and I'll show you how to put that into a workbook_open macro that protect ALL the sheets and gives access to the sheets for VBA changes.

You will want all sheets protecting EXCEPT A119, yes? Or that one, too? Be sure to think it through and give good information so we can get it right.

Once you start this stuff, it's always good to have an easy way to jump around in your workbook, so I converted the "column headers" to hyperlinks for you. There is another set of text labels above in row1, that is used to create a single formula in G2 that can be copied across and still work.

So, make your edits, click the UPDATE button, then use the hyperlinks to jump around quickly. I added a hyperlink on each aircraft sheet to make jumping back quick, too.

I used a temporary password of "password123" on all the sheets. I also created an "UnprotectALL" macro you can run manually from inside the VBEditor (ThisWorkbook module) to quickly unlock all sheets. There's a "ProtectAll" macro, too, and opening the workbook will run that macro for you every time.

Once you get it all finished, you might want to password protect the VBAProject as well so no one can see the code which includes the password.

They are in the ThisWorkbook module. Go into that module, click inside the macro code you want to run and press F5, it runs instantly.

An autofilter requires the data set be congruent. No blanks IN the middle of the data. Feel free to add/delete rows as you wish, but when you're done, no blanks, ok?

Also, make sure the gray rows have an "x" in all the cells all the way across, on every grey row. You want those rows to always be visible when the filter kicks in.

I tweaked the macro to remove the MRE search, so it now it copies everything and replaces everything each time it is run.

Option Explicit

Sub RemovableEquipment()
'Jerry Beaucaire  5/3/2010
Dim ws As Worksheet, wsA119 As Worksheet
Dim Col As Long     'column on A119 to filter
Dim LR  As Long     'last row of data

Application.ScreenUpdating = False
Set wsA119 = Sheets("A119 MASTER")
wsA119.Range("2:2").AutoFilter

For Each ws In Worksheets
    If ws.Name <> wsA119.Name Then
    'Remove current entries
        ws.Range("A6:E" & Rows.Count).ClearContents
    'Filter A119 for new data
        On Error GoTo ErrorHandler
        Col = wsA119.Rows(2).Find(What:=ws.Name, _
            After:=wsA119.[A2], LookIn:=xlValues, LookAt:=xlWhole, _
            SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False).Column
        On Error GoTo 0
        wsA119.Range("2:2").AutoFilter Field:=Col, Criteria1:="<>"
    'Test if any items to copy, copy them if so, copy all at once
        LR = wsA119.Cells(wsA119.Rows.Count, Col).End(xlUp).Row
        If LR > 2 Then
            wsA119.Range("A2:F" & LR).Copy
            ws.Range("A6").PasteSpecial xlPasteAll
        End If
Next1:
        wsA119.Range("2:2").AutoFilter Field:=Col
    End If
Next ws

wsA119.AutoFilterMode = False
Application.ScreenUpdating = True
Beep
Exit Sub

ErrorHandler:
    MsgBox "No column of data was found matching " & ws.Name & "," _
        & vbLf & "make a note and correct for next time if needed." _
        & vbLf & vbLf & "Continuing with next aircraft..."
    On Error GoTo 0
    GoTo Next1
End Sub

Thanks for that.

It's actually much easier to grab ALL the data and replace ALL the data on each sheet than it was to just do the one section, so even though it looks like the macro is working harder, it's actually moving more data by working less. Hehe...funny stuff.

========
If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.