Try this, remove all the other code and replace with:
Option Compare Text 'A=a, B=b, ... Z=z
Option Explicit
 
Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
Application.EnableEvents = False
On Error GoTo ErrorExit
    
    For Each Cell In Target
        Select Case Cell.Value
            Case vbNullString
                Cell.Interior.ColorIndex = xlNone
                Cell.Font.Bold = False
            Case "URGENT"
                Cell.Interior.ColorIndex = 3
                Cell.Font.Bold = True
            Case "Incoming"
                Cell.Interior.ColorIndex = 17
                Cell.Font.Bold = False
            Case "To Do"
                Cell.Interior.ColorIndex = 6
                Cell.Font.Bold = True
            Case "Outgoing"
                Cell.Interior.ColorIndex = 46
                Cell.Font.Bold = False
            Case "Completed"
                Cell.EntireRow.Copy
                Worksheets("Completed").Range("A" & Rows.Count).End(xlUp).Offset(1, 0).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
                Cell.EntireRow.Delete
            Case Else
                Cell.Interior.ColorIndex = xlNone
                Cell.Font.Bold = False
        End Select
    Next
    
ErrorExit:
Application.EnableEvents = True
End Sub