Link or Open file by date modified

My suggestion is to have your import macro MOVE the .csv files into an "IMPORTED" folder after it has done its work. Then your macro need only import any file it finds appearing in the main "watch" directory. If it sees a file appear, it imports it and moves it to the "IMPORTED" folder.

This alleviates all the overhead trying to parse filenames and/or file attributes.

Originally Posted by Burnsterboy

If I am understanding you correctly I still have to manually move a file to a different directory...

Originally Posted by JBeaucaire

My suggestion is to have your import macro MOVE the .csv files

Then you are not understanding me correctly. I suggested the macro you are using to import move the file when it's done with the import.

The VBA function NAME() allows you to move a file to another location effectively by renaming it. I have several macros that do this...import all the files in a single folder and move them when done. Here's one for you to look over:

PHP Code: 

Sub Consolidate()
'Author:     JBeaucaire'
'Date:       9/15/2009     (2007 compatible)'
'Summary:    Open all Excel files in a specific folder and merge data'
'            into one master sheet (stacked)'
'            Moves imported files into another folder'
Dim fName As String, fPath As String, fPathDone As String, OldDir As String
Dim LR As Long, NR As Long
Dim wbkOld As Workbook, wbkNew As Workbook, ws As Worksheet

'Setup'
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.DisplayAlerts = False
    
    Set wbkNew = ThisWorkbook
    wbkNew.Activate
    Sheets("Master").Activate   'sheet report is built into'
    
    If MsgBox("Import new data to this report?", vbYesNo) = vbNo Then Exit Sub
    
    If MsgBox("Clear the old data first?", vbYesNo) = vbYes Then
        Cells.Clear
        NR = 1
    Else
        NR = Range("A" & Rows.Count).End(xlUp).Row + 1
    End If

'Path and filename'
    OldDir = CurDir             'memorizes the current working path'
    fPath = "C:\My Documents\Trackers\"
    fPathDone = "C:\My Documents\Trackers\Imported\"
    ChDir fPath
    fName = Dir("*.xl*")      'filtering key, change to suit

'Import a sheet from found file'
    Do While Len(fName) > 0
        'Open file'
            Set wbkOld = Workbooks.Open(fName)
        'Find last row and copy data'
            LR = Range("A" & Rows.Count).End(xlUp).Row
            Range("A1:A" & LR).EntireRow.Copy _
                wbkNew.Sheets("Master").Range("A" & NR)
        'close file'
            wbkOld.Close False
        'Next row'
            NR = Range("A" & Rows.Count).End(xlUp).Row + 1
        'move file to IMPORTED folder'
            Name fPath & fName As fPathDone & fName
        'ready next filename'
            fName = Dir
    Loop

'Cleanup'
    ActiveSheet.Columns.AutoFit
    Application.DisplayAlerts = True
    Application.EnableEvents = True
    Application.ScreenUpdating = True

'restores original working path'
    ChDir OldDir
End Sub 


The section of code of relevance is:

        'move file to "imported" folder
            Name fPath & fName As fPathDone & fName

Naming a file and applying a different directory with the same filename effectively moves it. And this is far less hurdles to jump through than trying to decipher an ever-growing list of files for the latest addition.

Burnsterboy, if that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.
=======

FreshPrince, your post does not comply with forum rules #2 - do not post questions of your own in someone else's thread.

Create your own thread and include a link to this one if you find it relevant. You'll need to provide more information anyway.

If there is only ONE of these dated files each day, then this would find and open that one file:

Option Explicit

Sub OpenDatedCSV2()
Dim wbName As String, fPath As String

fPath = "C:\2009\"      'remember the last \ in this string
wbName = Dir("DailyReportSales." & Format(Date, "YYYYMMDD") & "*.csv")

If wbName <> "" Then Workbooks.Open fPath & wbName

End Sub

Does this get you started?

JBeaucaire,

What if the they need the most recent file, which may not be current date.

I am referring to this line from your latest post:

wbName = Dir("DailyReportSales." & Format(Date, "YYYYMMDD") & "*.csv")

For instance, what if they need to run this early in the morning and the latest file is prior day? Or 3 days prior after a weekend, etc.

Thats the particular problem I am having. I'll begin a new thread to discuss because it might be different from this topic.