Workbook automatically opens after closing

I have a workbook on a share drive that is used by multiple people. In the event that someone leaves the workbook open after using it, I have a timer function that pops up a splash screen after 4 minutes of inactivity which states, "This workbook will close in 1 minute if there is no further activity". If there is no further activity in that minute, the workbook closes.

The code works fine...unless the workbook is manually closed in that minute between the splash screen and when the timer would have closed the workbook. If that happens, the workbook closes normally and then briefly reopens and closes a minute later when the timer would have closed the workbook.

Is there any code to prevent this?

Public RunWhen As Double
Public Const cRunIntervalSeconds = 300 'FIVE minutes
Public Const cRunWhat = "CloseTheWorkbook"

Public SplashRunWhen As Double
Public Const cSplashRunIntervalSeconds = 240 'FOUR minutes
Public Const cSplashRunWhat = "SplashScreen_Open"


Sub Timer()
    RunWhen = Now + TimeSerial(0, 0, cRunIntervalSeconds)
    Application.OnTime EarliestTime:=RunWhen, Procedure:=cRunWhat, Schedule:=True
    
    SplashRunWhen = Now + TimeSerial(0, 0, cSplashRunIntervalSeconds)
    Application.OnTime EarliestTime:=SplashRunWhen, Procedure:=cSplashRunWhat, Schedule:=True
End Sub


Sub StopTimer()
    On Error Resume Next
    Application.OnTime EarliestTime:=RunWhen, Procedure:=cRunWhat, Schedule:=False
    Application.OnTime EarliestTime:=SplashRunWhen, Procedure:=cSplashRunWhat, Schedule:=False
End Sub


Sub CloseTheWorkbook()
With ActiveWorkbook
    .RunAutoMacros xlAutoClose
    .Save
    .Close
End With
End Sub


Sub SplashScreen_Open()
    SplashScreen.Show
End Sub

Hi SJB
blane245 is correct; you need to stop the timer when you close the workbook else, unless you've also closed the Excel session, the timer will reopen the workbook and run again. I discovered this after many frustrating hours 6 or 8 months ago.
The way I solved my issue was to create a Worksheet Before Close Event such as this

Private Sub Workbook_BeforeClose(Cancel As Boolean)
        Call StopTimer
End Sub

and that did the trick for me.
John

Hi Steve
Be glad to help if I can. Open your workbook then open VBA (ALT F11 or select Developer Tab, then Visual Basic. On the left side, you'll see "This Workbook". Double click on "This Workbook". Copy this code

Private Sub Workbook_BeforeClose(Cancel As Boolean)
        Call StopTimer
End Sub

and paste it to the right pane in your VBA screen. I don't know the consequences of running your files on a shared drive but I believe this should work. That should do it.
If you have issues or can't figure out the process, let me know. I'll be glad to help further.
John