Save As sub not saving

The dialog box comes up with file name formatted correctly and shows .xls as file type but when you choose save the dialog box disappears as if the file was saved but the file never gets saved. What am I doing wrong?

Sub SaveAs()
    Dim TName As String
    Dim SvAs As String
    TechName = Range("N5").Value
    SvAs = Application.GetSaveAsFilename(InitialFileName:="Test Sheet for " & TName, FileFilter:="Excel Workbook (*.xls), *.xls", Title:="Save Workbook with Name")
End Sub

Thanks much for any help.
Barry

I would avoid naming a sub SaveAs, since there is a method by that name.

GetSaveAsFileName returns a path (a string), but doesn't actualy save the file.
You could either:
Add a bit that saves the workbook

Sub mySaveAs()
    Dim TName As String
    Dim SvAs As String
    TName = Range("N5").Value
    SvAs = Application.GetSaveAsFilename(InitialFileName:="Test Sheet for " & TName, FileFilter:="Excel Workbook (*.xls), *.xls", Title:="Save Workbook with Name")
    If SvAs <> "False" Then
        ThisWorkbook.SaveAs Filename:=SvAs
    Else
        MsgBox "Cancel pressed"
    End If

or you could use the built in dialog

Sub trial()
    Dim TName As String
    TName = Range("N5").Value
    If Application.Dialogs(xlDialogSaveAs).Show("Test Sheet for " & TName) Then
        MsgBox "File saved as: " & ThisWorkbook.Name
    Else
        MsgBox "File not saved"
    End If
End Sub

Hello Barry,

The GetSaveAsFilename only returns the file name along with its directory path. It doesn't actually do the saving. You have to do that.