Copy and paste data if row in Column N is empty.

Here is my current code

Sub Demand()
Sheets("Demand").Range("N2:N ").Value = _
Sheets("Demand").Range("P2:P").Value
Sheets("Demand").Range("Q2:P").Value
Sheets("Demand").Range("S2:P").Value
Sheets("Demand").Range("T2:P").Value
Sheets("Demand").Range("V2:P").Value
Sheets("Demand").Range("W2:P").Value
Sheets("Demand").Range("Y2:P").Value
Sheets("Demand").Range("Z2:P").Value
Sheets("Demand").Range("AE2:P").Value
Sheets("Demand").Activate
End Sub

I am trying to go down every row in Column N. If a row in Column N is empty I’d like to go to Column P copy the data and paste into Column N. If Column P is empty I’d like to go to Column Q copy the data and paste into Column N. If Column Q is empty I’d like to go to Column S copy the data and paste into Column N. If Column S is empty I’d like to go to Column T copy the data and paste into Column N. If column T is empty I’d like to go to Column V copy the data and paste into Column N. If Column V is empty go to Column W copy the data and paste into Column N. If Column W is empty go to Column Y copy the data and paste into Column N. If Column Y is empty go to Column Z copy the data and paste into Column N. If Column Z is empty go to Column AE copy the data and paste into Column N.

As am I sure you can see my current macro will not accomplish what I am aiming to do. Can you help?

Welcome to the forum.

Maybe like this:

Sub Demand()
    Dim cell        As Range
    Dim v           As Variant

    For Each cell In Intersect(ActiveSheet.UsedRange, Columns("N"))
        If IsEmpty(cell.Value) Then
            For Each v In Array("P", "Q", "S", "T", "V", "W", "Y", "Z", "AE")
                If Not IsEmpty(Cells(cell.Row, v).Value) Then
                    cell.Value = Cells(cell.Row, v).Value
                    Exit For
                End If
            Next v
        End If
    Next cell
End Sub

Wow,Shg, this is a beautiful thing. Thank you for helping me with this bud; the macro is better than I imagined.