Best way to parse colums and rows w/ multiple values separated by comma?

I routinely have do download massive data sets of reporting that is saved as an excel spreadsheet. The three columns of sample data attached are Report Numbers, Report Evaluation Serial Numbers, and Report Evaluator ID.
As seen in the attached spreadsheet, there can be multiple Report Numbers (in same field separated by comma) which have been evaluated by different Evaluators. It is my responsibility to account for the number of Reports that have been evaluated, and many other metrics from like data. The issue I have is when more than one report number is listed in the same field I need to parse the data into its own field for ease of counting (and also maintain the adjacent data). It is not a problem to merely copy the fields and delete the excess numbers, however when dealing with thousands of Reports, and Evaluators this can be very time consuming. In the attached file I have separated .xls into three workbooks to help explain my problem: Initial state of Data; What I need To Parse Out; and The final endstate I require. I hope that I have explained this issue with enough detail. I am sure that the attached file will explain better.

Any help in this matter will be greatly appreciated!

See if the below is of interest - designed to run against your "Initial State of Information" sheet - ie alters original data (run on a test first!)

Public Sub Example()
Dim xlCalc As XlCalculation, lngRow As Long, vData
On Error GoTo ExitPoint
With Application
    xlCalc = .Calculation
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
    .EnableEvents = False
End With
For lngRow = Cells(Rows.Count, "A").End(xlUp).Row To 2 Step -1
    With Cells(lngRow, "A")
        vData = Split(.Value, ",")
        If UBound(vData) Then
            .Offset(1).EntireRow.Resize(UBound(vData)).Insert
            .Resize(UBound(vData) + 1).Value = Application.Transpose(vData)
            .Offset(, 1).Resize(UBound(vData) + 1, 2).Value = .Offset(, 1).Resize(, 2).Value
        End If
    End With
Next lngRow
ExitPoint:
With Application
    .ScreenUpdating = True
    .Calculation = xlCalc
    .EnableEvents = True
End With
End Sub

Not entirely sure I follow but perhaps try altering:

.Offset(, 1).Resize(UBound(vData) + 1, 2).Value = .Offset(, 1).Resize(, 2).Value

to

.Offset(, 1).Resize(UBound(vData) + 1, 11).Value = .Offset(, 1).Resize(, 11).Value

so instead of simply copying down B:C you're now copying down B:L