Deleting Content of a Cell till the End of Right (Not Row)

Dear All,

I need help on Excel 2007 Macro , the below coding searches for a string "recvtiming" in a cell as a wildcard and delete it entire row once it founds it in a single active sheet.

Question,
1. How do I manipulate it to search for the same string and upon finding
a) Delete its cell content and all the contents from its right hand of side till its last column which have a value from the same row on all 50 sheets in the workbook.

e.g
a b c d recv 0 1 2 3 4

It should return,
a b c d

====================Start Code ====================

With ActiveSheet
    .Select

    ViewMode = ActiveWindow.View
    ActiveWindow.View = xlNormalView
    .DisplayPageBreaks = False

    Firstrow = .UsedRange.Cells(1).Row
    Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row
        
    'Loop from Firstrow to Lastrow
    For Lrow = Firstrow To Lastrow
        
    Firstcol = .UsedRange.Cells(1).Column
    Lastcol = .UsedRange.Columns(.UsedRange.Columns.Count).Column
    Currentcell = ActiveCell.Address.Column
        
            If Application.CountIf(.Rows(Lrow), "recv*") > 0 Then Range(Cells(Lrow, Currentcell), Cells(Lrow, Lastcol)).ClearContents
            
    Next Lrow

End With

====================End Code ====================

Hello svanan,

Welcome to the Forum!

This macro will look through all the worksheets and find all occurances of "revtiming" and delete the data in that cell and all others to the right in the same row.

Sub DeleteColumns()

  Dim FirstAddx As String
  Dim FoundIt As Range
  Dim LastCol As Long
  Dim What As String
  Dim Wks As Worksheet
  
    What = "recvtiming"
    
    For Each Wks In Worksheets
      LastCol = Wks.UsedRange.Columns.Count
      Set FoundIt = Wks.UsedRange.Find(What, , xlValues, xlWhole, xlByColumns, xlNext, False)
      If Not FoundIt Is Nothing Then
         FirstAddx = FoundIt.Address
           Do
             FoundIt(1, LastCol - FoundIt.Column).ClearContents
             Set FoundIt = Wks.UsedRange.FindNext(FoundIt)
           Loop While Not FoundIt Is Nothing And FoundIt.Address <> FirstAddx
      End If
   Next Wks
   
End Sub

Try this:

Sub DeleteColumns()
    Dim rFind       As Range
    Dim wks         As Worksheet

    For Each wks In ActiveWorkbook.Worksheets
        With wks
            Set rFind = .UsedRange.Find(What:="recvtiming", _
                                        LookIn:=xlValues, _
                                        LookAt:=xlWhole, _
                                        MatchCase:=False)
            Do Until rFind Is Nothing
                .Range(rFind, .Cells(rFind.Row, .Columns.Count)).ClearContents
                Set rFind = .UsedRange.FindNext(rFind)
            Loop
        End With
    Next wks
End Sub