Nested loop to concatenate 2 columns of data

Hi,

I think I just need a basic Nested For Loop code...

I have a list of in column A, from A1:A537

and another list in column B, for B1:B50

I want to add a column that concatenates,

each item in Column A to B1 (so 537 rows), then again each item in Column A to B2, another 537 rows, etc.. this loop is repeated 50 times, one for each name in column B.

Hello JohnnyBGood,

Here is a macro you can use. It uses column "C" as the helper column.

Sub ConcatenationLoop()

  Dim RngA As Range
  Dim RngB As Range
  Dim RngC As Range
  Dim I As Long
  Dim J As Long
  Dim N As Long
  
    Set RngA = Range("A1:A537")
    Set RngB = Range("B1:B50")
    Set RngC = Range("C1")
    
      For I = 1 To RngB.Rows.Count
        For J = 1 To RngA.Rows.Count
          N = N + 1
          RngC.Cells(N, 1) = RngA.Cells(J, 1) & RngB.Cells(I, 1)
        Next J
      Next I
      
End Sub

There is no need for a loop

Sub test()
    Dim lastA As Long
    With ThisWorkbook.Sheets("sheet1")
        lastA = .Cells(.Rows.Count, 1).End(xlUp).Row
        With Cells(1, 5).Resize(lastA * .Cells(.Rows.Count, 2).End(xlUp).Row, 1)
            .FormulaR1C1 = "=OFFSET(R1C1,MOD(ROW(RC1)-1," & lastA & "),0)" & "&OFFSET(R1C2,INT((ROW(RC1)-1)/" & lastA & "),0)"
            .Value = .Value
        End With
    End With
End Sub