Looping FindFormat with relative cell update

Using Excel 2007 and VBA code, I am trying to find all cells in a worksheet with a particular number format ("#,##0.00 ""INR"). For each of these cells I would like to update the cell in the column directly to the right with the value "YES". I have recorded a macro to find the correct format and modified my code to change the value of the cell and everything looks great. However, I cannot figure out the correct way to loop through the sheet once and perform the same function for each of the cells matching the format criteria. Any help is appreciated. Below is my code so far:
----

Sub Find_Format_INR()
'
' Find_Format_INR Macro
'
    

    Application.FindFormat.NumberFormat = "#,##0.00 ""INR"""
    Cells.Find(what:="", after:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , searchformat:=True).Activate
    ActiveCell.Offset(0, 1).Range("A1").Select
    ActiveCell.FormulaR1C1 = "YES"
    ActiveCell.Offset(0, 1).Range("A1").Select
    
End Sub

Hello adamspain,

This macro will loop through the cells on the ActiveSheet and when a match is found set the cell, one column to the right of the matched cell, equal to "Yes".

Sub Find_Format_INR()
'
' Find_Format_INR Macro
'
  Dim FirstAddx As String
  Dim FoundIt As Range
  Dim Rng As Range

    Application.FindFormat.NumberFormat = "#,##0.00 ""INR"""
    
    Set Rng = ActiveSheet.UsedRange
    Set FoundIt = Rng.Find(what:="", after:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
                           xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                           MatchCase:=False, searchformat:=True)
    If Not FoundIt Is Nothing Then
       FirstAddx = FoundIt.Address
         Do
           FoundIt.Offset(0, 1) = "YES"
           Set FoundIt = Rng.FindNext(FoundIt)
         Loop While Not FoundIt Is Nothing And FoundIt.Address <> FirstAddx
    End If
    
End Sub

Hello adamspain,

Sorry it didn't work out, but I don't have Excel 2007. The macro is a composite based on Excel 2003 functionality and the code differences you included in your post.

The macro is checking all cells on the worksheet as per your request. Whether the code for checking the format is correct, I can not say.

Using Excel 2007 and VBA code, I am trying to find all cells in a worksheet with a particular number format ("#,##0.00 ""INR").
For each of these cells I would like to update the cell in the column directly to the right with the value "YES".

You really need someone who has Excel 2007 to look into why this isn't working.

IIRC, FindNext ignores the FindFormat, so try a small tweak:

Sub Find_Format_INR()
'
' Find_Format_INR Macro
'
  Dim FirstAddx As String
  Dim FoundIt As Range
  Dim Rng As Range

    Application.FindFormat.NumberFormat = "#,##0.00 ""INR"""
    
    Set Rng = ActiveSheet.UsedRange
    Set FoundIt = Rng.Find(what:="", after:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
                           xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                           MatchCase:=False, searchformat:=True)
    If Not FoundIt Is Nothing Then
       FirstAddx = FoundIt.Address
         Do
           FoundIt.Offset(0, 1) = "YES"
           Set FoundIt = Rng.Find(what:="", after:=FoundIt, LookIn:=xlFormulas, LookAt:= _
                           xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
                           MatchCase:=False, searchformat:=True)
         Loop While FoundIt.Address <> FirstAddx
    End If
    
End Sub