if image is present, adjust autoshape

You still need to be using the TopLeftCell property in order to determine a shapes position relative to the worksheet.

Maybe things would be clearer if you posted small example file

try this

Sub testy()

    Dim pic As Shape, star As Shape
    
    'make all stars on "VIP" white
    For Each star In Sheet1.Shapes
    
        If star.TopLeftCell.Column = 10 Then star.Fill.ForeColor.SchemeColor = 9
        
    Next star
                
    'look for pics in col B of "Picture" and change
    'corresponding star on same row of "VIP" to yellow
    For Each pic In Sheet2.Shapes
    
        If pic.Type = msoPicture And pic.TopLeftCell.Column = 2 Then
        
            For Each star In Sheet1.Shapes
            
                With star
                
                    If .TopLeftCell.Row = pic.TopLeftCell.Row And .TopLeftCell.Column = 10 _
                         Then .Fill.ForeColor.SchemeColor = 13
                    
                End With
                
            Next star
            
        End If
    
    Next pic

End Sub

This takes a different approach using webdings2 font rather than images.

The user defined function returns true or false if the picture is there on sheet picture.

Public Function UDF_HASPICTURE(SheetName As String, CellAddress As String) As Boolean
    
    Dim shtTemp As Worksheet
    Dim rngCheck As Range
    Dim shpTemp As Shape
    
    On Error GoTo ErrHasPicture
    
    If Len(SheetName) = 0 Then
        ' use active sheet
        Set shtTemp = ActiveSheet
    Else
        Set shtTemp = Worksheets(SheetName)
    End If
    
    Set rngCheck = shtTemp.Range(CellAddress)
    
    If Not shtTemp Is Nothing Then
        For Each shpTemp In shtTemp.Shapes
            If Not Intersect(shpTemp.TopLeftCell, rngCheck) Is Nothing Then
                UDF_HASPICTURE = True
                Exit For
            End If
        Next
    End If
    
ErrHasPicture:
    Exit Function
    
End Function

The formula would be

=IF(UDF_HASPICTURE("Picture","B" & ROW()),"é","")