printing to a printer without asking which printer

**cuewoz** · 08-19-2009, 11:42 AM

Hi

I know from a search how to get a list of available printers on a PC, and I know by recording a macro how to get a printer as the active printer which the print goes to.

What I need is how to get a command to set a active printer from a list of printers?

Is there a way to generate a list of printers on a pc, but to display them with the necessary network parts attached eg

Application.ActivePrinter = "\\TS2K-SHEFFIELD\FLOWLAB2600n on Ne03:"

, also some are not networked -

Application.ActivePrinter = "HP Business Inkjet 1200 Series on LPT1:"

This is to bypass the pop up dialog box selecting the printer, as it will always be the laser printer and not any of the others, I know you could set it up so the user selects the pc they are working on, but the might as well select the printer.

**Leith Ross** · 08-19-2009, 12:41 PM

Hello cuewoz,

This macro should provide a good starting point. It lists the available printers as you describe, but this code is for computers that use NTFS (Windows NT File Structure). You don't mention which operating system you are using either in your post in your profile. If you are using Windows 2000 or later then this macro should run.

'Written: April 15 ,2009
'Author:  Leith Ross
'Summary: Lists the printers and ports that are available to the user.

Sub PrintersAndPorts()

 'This works with Windows 2000 and up
 
  Dim Arr As Variant
  Dim Device As Variant
  Dim Devices As Variant
  Dim Msg As String
  Dim RegObj As Object
  Dim RegValue As String
  Const HKEY_CURRENT_USER = &H80000001
       
    Set RegObj = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
    RegObj.enumvalues HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Devices, Arr
    
      For Each Device In Devices
          RegObj.getstringvalue HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Device, RegValue
          Msg = Msg & Device & " on " & Split(RegValue, ",")(1) & vbCrLf
      Next
      
    MsgBox Msg, vbInformation, "Printers and Ports"
      
End Sub