How can I identify Duplicates in a column?

Hello RDMRDM,

Here is macro to remove the duplicates. This works with Excel 2000 and later. This starts at "I1" of the Active Sheet. You can change the starting cell if you need to. It is marked in red. Run this on a copy of your data to be sure it works like you want.

Sub DeleteDups()

  Dim DSO As Object
  Dim Data As Variant
  Dim I As Long
  Dim Key As Variant
  Dim Rng As Range
  
    Set Rng = ActiveSheet.Range("I1")
    Set RngEnd = Rng.Parent.Cells(Rows.Count, Rng.Column).End(xlUp)
    Set Rng = IIf(RngEnd.Row < Rng.Row, Rng, Rng.Parent.Range(Rng, RngEnd))
    
    Set DSO = CreateObject("Scripting.Dictionary")
    DSO.CompareMode = vbTextCompare
    
      Data = Rng.Value
      
      For I = 1 To UBound(Data, 1)
        Key = Trim(Data(I, 1))
        If Not DSO.Exists(Key) Then
          DSO.Add Key, 1
        Else
          Rng.Cells(I, 1) = ""
        End If
      Next I
      
    On Error Resume Next
    Set Rng = Rng.SpecialCells(xlCellTypeBlanks)
    If Err = 0 Then Rng.EntireRow.Delete
    
    Set DSO = Nothing
    
End Sub

Adding the Macro
1. Copy the macro above pressing the keys CTRL+C
2. Open your workbook
3. Press the keys ALT+F11 to open the Visual Basic Editor
4. Press the keys ALT+I to activate the Insert menu
5. Press M to insert a Standard Module
6. Paste the code by pressing the keys CTRL+V
7. Make any custom changes to the macro if needed at this time.
8. Save the Macro by pressing the keys CTRL+S
9. Press the keys ALT+Q to exit the Editor, and return to Excel.

To Run the Macro...
To run the macro from Excel, open the workbook, and press ALT+F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.