Minus sign at the end of number

The following macro will do what you want I hope

Option Explicit

Sub replace_right_minus()
Dim found As Range
Dim cellcontent As Variant
Dim first_no_change_addr As String

With ActiveSheet.UsedRange
    On Error Resume Next
    ' Look for cells ending with a '-'
    Set found = .Find(what:="*-", LookIn:=xlValues, lookat:=xlWhole)
    On Error GoTo 0
    If Not found Is Nothing Then
        Do
            ' Extract the cell content for everything apart from the '-'
            cellcontent = Left(found.Value, Len(found.Value) - 1)
            
            ' If the cell contents are numeric then flip the '-' to the left, otherwise record the first found non-numeric cell
            If IsNumeric(cellcontent) Then
                found.Value = Left(found.Value, Len(found.Value) - 1) * -1
            ElseIf first_no_change_addr = "" Then
                first_no_change_addr = found.Address
            End If
            ' Look for the next matching cell
            Set found = .FindNext(found)
            ' If nothing is found, stop looking
            If found Is Nothing Then Exit Do
        Loop While found.Address <> first_no_change_addr ' if we find a cell we've already decided not to change, stop looking
    End If
End With
MsgBox "Completed"
End Sub

Here's another way:

Sub x()
    Dim rCol As Range
    
    For Each rCol In ActiveSheet.UsedRange.Columns
        If WorksheetFunction.CountA(rCol) Then
            rCol.TextToColumns Destination:=rCol(1), TrailingMinusNumbers:=True
        End If
    Next rCol
End Sub

@shg

Ooo - thats snazzy, I wasn't aware of that function

Note though that it will cause a problem if a cell contains a value such as "-Note: This cell starts with a dash".

Of course to enter that text you have to start it with a single quote ' , then Excel accepts that as text and not a formula, but your macro seems to break that when it runs.

Not sure if thats a problem or not for the OP, but thought I'd better point it out

it will cause a problem if a cell contains a value such as "-Note:

It's a fair wind that blows no ill ...