Error Detection

A common practice is to declare procedures as Boolean functions and have them return True if successful.

A function can (and frequently does) return value(s) in its argument(s).

Sub x()
    Dim d As Double
    
    d = 5
    If mySqrt(d) Then MsgBox d
    
    d = -1
    If mySqrt(d) Then MsgBox d
End Sub

Function mySqrt(ByRef d As Double) As Boolean
    If d > 0 Then
        mySqrt = True
        d = Sqr(d)
    End If
End Function

Ok, I see how this can work, but it still requires me to turn each and every function call into an If statment. There has to be a cleaner way to check for errors.

How about this:

If I define an Error function in each UserForm, and have it display a message and execute Unload Me, is there then a way to call that function from a public function without knowing necesaraly who called the public function.

So... is there a way for a public function to know who (what function/sub) called it, and then execute a public function from within that calling object?

You can have an error handler in the calling procedure:

Sub x()
    Dim d As Double
    
    On Error GoTo Oops
    d = mySqrt(-5)
    Exit Sub
    
Oops:
    MsgBox "Error " & Err.Number & ": " & Error(Err.Number), , "Oops!"
End Sub

Function mySqrt(d As Double) As Double
    mySqrt = Sqr(d)
End Function

Provide more information if you like:

Sub x()
    Dim d       As Double
    Dim s       As String

    On Error GoTo Oops

    d = mySqrt(-5)
    s = MyFilefinder("C:\unlikely.txt")

    Exit Sub

Oops:
    MsgBox "Error " & Err.Number & _
           " in module " & _
           Err.Source & _
           ": " & Err.Description
    Resume Next    ' or skip this to just exit
End Sub

Function mySqrt(d As Double) As Double
    On Error Resume Next
    mySqrt = Sqr(d)
    If Err.Number Then
        On Error GoTo 0
        Err.Raise 513, "mySqrt"
    End If
End Function

Function MyFilefinder(sFile As String) As String
    MyFilefinder = Dir(sFile)
    If Len(MyFilefinder) = 0 Then Err.Raise 514, "MyFileFinder", "File not found!"
End Function

Soo ... try it