userform return value

I call a userform and need to determine whether the user clicked "OK" or "Cancel" on the form. Is there a way to do this without setting a global variable and checking it after the form is closed?

I want to say something like:

 myInt = userForm1.run

where "run" is a method in userForm1 that returns a different value for OK and Cancel. But I don't know how to make this happen.

Thanks Andy!

Here's how I do it for my userforms.

standard code module

Sub Test()

    Dim frmTest As UserForm1
    
    Set frmTest = New UserForm1
    
    If frmTest.UserCancel Then
        MsgBox "User cancelled"
    Else
        MsgBox "User closed as expected"
    End If
    
    Unload frmTest
    Set frmTest = Nothing
    
End Sub

Userform1 with 2 buttons
code

Private m_blnUserCancelled As Boolean
Public Function UserCancel() As Boolean

    m_blnUserCancelled = True
    
    Me.Show
    
    UserCancel = m_blnUserCancelled
    Exit Function
    
End Function

Private Sub CommandButton1_Click()
    Me.Hide
End Sub

Private Sub CommandButton2_Click()

    m_blnUserCancelled = False
    Me.Hide
    
End Sub