Need to make certain text bold in a comment using vba

**Bravurian17** · 05-25-2009, 08:08 PM

I need to figure out how to make certain text bold in a comment using vba. I'm making it so it adds a comment that looks like this:
Untitled.jpg
I've searched other forums and none have helped. I need to do this in vba. Thanks in advance.

**Leith Ross** · 05-25-2009, 11:58 PM

Hello Bravurian17,

Welcome to the Forum!

You will need to make some changes to this macro, but it does what you want. The cell address, start date, end date, and place strings are marked in red. Change these to what you are using.

Sub MacroX()

  Dim Cmnt As Comment
  Dim I As Long
  Dim L As Long
  Dim Msg As String
  Dim Rng As Range
  
    Msg = Environ("username") & vbLf & vbLf _
        & "Start:" & vbLf & "date" & vbLf & vbLf _
        & "End:" & vbLf & "date" & vbLf & vbLf _
        & "Where:" & vbLf & "place" & vbLf & vbLf
        
    Set Rng = Range("$C$1")
    Set Cmnt = Rng.Comment
    
      If Cmnt Is Nothing Then
        Rng.AddComment Msg
      Else
        Cmnt.Shape.TextFrame.Characters.Text = ""
        Cmnt.Shape.TextFrame.AutoSize = True
        Cmnt.Shape.TextFrame.Characters.Text = Msg
      End If
      
      L = Len("Start:")
      I = InStr(1, Msg, "Start:")
        Cmnt.Shape.TextFrame.Characters(I, L).Font.Bold = True
        Cmnt.Shape.TextFrame.Characters(I + L, Len(Msg) - (I + L + 1)).Font.Bold = False
        
      L = Len("End:")
      I = InStr(1, Msg, "End:")
        Cmnt.Shape.TextFrame.Characters(I, L).Font.Bold = True
        Cmnt.Shape.TextFrame.Characters(I + L, Len(Msg) - (I + L + 1)).Font.Bold = False
        
      L = Len("Where:")
      I = InStr(1, Msg, "Where:")
        Cmnt.Shape.TextFrame.Characters(I, L).Font.Bold = True
        Cmnt.Shape.TextFrame.Characters(I + L, Len(Msg) - (I + L + 1)).Font.Bold = False
    
End Sub