Click on 1 cell to goto another worksheet

Hi All,

Apologies if this has already been done but I cannot find it.

I am trying to click one 1 cell, which will automatically use a lookup of the cell values and find the correct sheet to go to.
All of this using VBA.

I have attached an example

Thanks

can you tell us which cells should react to being clicked

right click summary sheet tab and pick View code.
paste following.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim vntMatch As Variant
    
    If Target.Cells.Count > 1 Then Exit Sub
    If Not Intersect(Range("C4:C6"), Target) Is Nothing Then
        On Error Resume Next
        vntMatch = Application.WorksheetFunction.Match(Target.Value, Worksheets("Info").Range("B1:B3"), 0)
        If Not IsError(vntMatch) Then
            Application.Goto Worksheets(Worksheets("Info").Range("B1:B3").Cells(vntMatch).Offset(0, -1).Value).Range("A1"), True
        End If
        On Error GoTo 0
    End If
    
    
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Dim vntMatch As Variant
    Dim shtTemp As Worksheet
    
    If Target.Cells.Count > 1 Then Exit Sub
    If Not Intersect(Range("C4:C6"), Target) Is Nothing Then
        On Error Resume Next
        vntMatch = Application.WorksheetFunction.Match(Target.Value, Worksheets("Info").Range("B1:B3"), 0)
        If Not IsError(vntMatch) Then
            Set shtTemp = ThisWorkbook.Worksheets(Worksheets("Info").Range("B1:B3").Cells(vntMatch).Offset(0, -1).Value)
            If shtTemp Is Nothing Then
                ' no sheet do nothing
            Else
                If shtTemp.Visible <> xlSheetVisible Then
                    shtTemp.Visible = xlSheetVisible
                End If
                Application.Goto shtTemp.Range("A1"), True
            End If
        End If
        On Error GoTo 0
    End If
    
    
End Sub