Export Sheets to a New workbook

Hi there

I use this code to export sheets to a new workbook.

Sub ExportSheet()
Dim WB As Workbook
Dim FN As Variant
Worksheets(array("Sheet1", "Sheet2")).Copy
Set WB = ActiveWorkbook
FN = Application.GetSaveAsFilename( _
FileFilter:="Excel Files (*.xla), *.xla", _
Title:="Specify Location for Copy:")
If FN = False Then
WB.Close Savechanges:=False
Else
WB.SaveAs Filename:=FN
WB.Close Savechanges:=False
End If
End Sub

How ever, the exported sheets transport all properties and links existing in some cells. What I would like to know:

Is it possible to export those sheets and delete or convert existing links and some formulas?

Thank you all

You just want to replace all formulas with their values on those two sheets?

Maybe like this:

Sub ExportSheet()
    Dim sFile   As String
    Dim avLink  As Variant
    Dim vLink   As Variant

    Worksheets(Array("Sheet1", "Sheet2")).Copy

    With ActiveWorkbook
        sFile = Application.GetSaveAsFilename( _
                FileFilter:="Excel Files (*.xla), *.xla", _
                Title:="Specify Location for Copy:")
        
        If sFile <> "False" Then
            avLink = .LinkSources(xlExcelLinks)
            For Each vLink In avLink
                .BreakLink Name:=vLink, Type:=xlLinkTypeExcelLinks
            Next vLink

            .SaveAs Filename:=sFile
        End If
        .Close SaveChanges:=False
    End With
End Sub

You're welcome, thanks for the feedback.