Search columns and paste rows

Hi I have an excel spreadsheet with:
2 sheets,Sheet1 and Sheet2
4 columns (A,B,C,D)
100,000s of rows.

I need to search 3 columns, B,C and D, for particular values.
Column B needs to be = 0
Columns C and D need to be "<=0.1"

When all three criteria in the row are matched I need the value from column A in that row to be pasted to Sheet2 and then for the macro to continue searching the rows.

I have attached an extract of the data as the files size is too large to upload.

Welcome to the Board.

Something along the lines of the below perhaps ?

Public Sub FilterData()
Dim rngArea As Range
Sheets("sheet2").Columns(1).Clear
Sheets("Sheet1").Select
With Range(Cells(1, Columns.Count), Cells(Rows.Count, "A").End(xlUp).Offset(, Columns.Count - 1))
    .FormulaR1C1 = "=IF(AND(RC2=0,RC3<=0.1,RC4<=0.1),1,""x"")"
    For Each rngArea In .SpecialCells(xlCellTypeFormulas, xlNumbers).Areas
        Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(rngArea.Rows.Count).Value = rngArea.Offset(, 1 - Columns.Count).Value
    Next rngArea
    .Clear
End With
End Sub

Public Sub FilterData()
Dim rngArea As Range, xlCalc As XlCalculation
On Error GoTo Handler
With Application
    xlCalc = Application.Calculation
    .Calculation = xlCalculationManual
    .Application.ScreenUpdating = False
    .EnableEvents = False
End With
Sheets("sheet2").Columns(1).Clear
Sheets("Sheet1").Select
With Range(Cells(1, Columns.Count), Cells(Rows.Count, "A").End(xlUp).Offset(, Columns.Count - 1))
    .FormulaR1C1 = "=IF(RC2=4,1,""x"")"
    For Each rngArea In .SpecialCells(xlCellTypeFormulas, xlNumbers).Areas
        Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(rngArea.Rows.Count, 4).Value = rngArea.Offset(, 7 - Columns.Count).Resize(, 4).Value
    Next rngArea
    .Clear
End With
ExitPoint:
With Application
    .Calculation = xlCalc
    .Application.ScreenUpdating = True
    .EnableEvents = True
End With
Exit Sub

Handler:
MsgBox "Error etc...", vbCritical, "Error"
Resume ExitPoint

End Sub

Others may suggest Auto Filter... given the volume of data I don't know how feasible that is... I added in some Application events given that fact (re: calculation, screenupdating and events)

I get an error when I run it in the full data sheet. The start of the data sheet is the file attached previously

The code I posted worked for me with your prior sample file
(I'd not have posted it otherwise)

Re: your PM ... I'm not sure I understand the scenarios you posted previously.... are these independent processes ?

Please provide a sample with "before(s)" & "after(s)" such that I can see the logic in action.

I neither have the time nor inclination to create a test file for this so the below is untested, next time please provide a sample file as requested.

Public Sub FilterData()
Dim rngArea As Range, xlCalc As XlCalculation
On Error GoTo Handler
With Application
    xlCalc = Application.Calculation
    .Calculation = xlCalculationManual
    .Application.ScreenUpdating = False
    .EnableEvents = False
End With
Sheets("sheet2").Columns(1).Clear
Sheets("Sheet1").Select
With Range(Cells(1, Columns.Count), Cells(Rows.Count, "A").End(xlUp).Offset(, Columns.Count - 1))
    .FormulaR1C1 = "=IF(OR(RC2=0,RC3=0.2,RC3=-0.1),1,""x"")"
    For Each rngArea In .SpecialCells(xlCellTypeFormulas, xlNumbers).Areas
        Sheets("Sheet2").Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(rngArea.Rows.Count).Value = rngArea.Offset(, 1 - Columns.Count).Value
    Next rngArea
    .Clear
End With
ExitPoint:
With Application
    .Calculation = xlCalc
    .Application.ScreenUpdating = True
    .EnableEvents = True
End With
Exit Sub

Handler:
MsgBox "Error etc...", vbCritical, "Error"
Resume ExitPoint

End Sub