VBA stopped working!!

Yesterday I received great help from everyone on the code below. It worked perfectly allowing me to select more than one item in a drop down.

Today it stopped working. I had copied the file with a new name and changed the target column to 14 (Column N) and it did not work.

I went back to the original file with column 10 and it does not work either. Any ideas would be appreciated.....thanks again Max
-----------------------------------------------------

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim sOld    As String
    Dim sNew    As String
    Dim rVal    As Range

    If Target.Column <> 14 Then Exit Sub


    On Error Resume Next
    Set rVal = Me.Cells.SpecialCells(xlCellTypeAllValidation)
    If rVal Is Nothing Then Exit Sub
    On Error GoTo 0

    If Not Intersect(Target, rVal) Is Nothing Then
        Application.EnableEvents = False
        sNew = Target.Value
        Application.Undo
        sOld = Target.Value

        If Len(sNew) = 0 Then
            Target.ClearContents
        ElseIf Len(sOld) = 0 Then
            Target.Value = sNew
        Else
            Target.Value = sOld & ", " & sNew
        End If

        Application.EnableEvents = True
    End If
End Sub

It only works for cells in col 14 that have data validation.

You also took out the test for target.count > 1, which will result in a runtime error if multiple cells with validation are changed simultaneously.

OK how does this look?? It still doesn't seem to work...I made column N a validation...

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim sOld    As String
    Dim sNew    As String
    Dim rVal    As Range

    If Target.Column <> 14 Then Exit Sub
     If Target.Count > 1 Then Exit Sub

    On Error Resume Next
    Set rVal = Me.Cells.SpecialCells(xlCellTypeAllValidation)
    If rVal Is Nothing Then Exit Sub
    On Error GoTo 0

    If Not Intersect(Target, rVal) Is Nothing Then
        Application.EnableEvents = False
        sNew = Target.Value
        Application.Undo
        sOld = Target.Value

        If Len(sNew) = 0 Then
            Target.ClearContents
        ElseIf Len(sOld) = 0 Then
            Target.Value = sNew
        Else
            Target.Value = sOld & ", " & sNew
        End If

        Application.EnableEvents = True
    End If
End Sub

Does the cell you're changing have validation?

Have you closed and reopened Excel to make sure events are enabled?

If yes to both of the above, post the workbook again, Max.