Apply Border based on change in cell value?

I currently have 200 Rows of data with Column H being a value of 1-12. I would like sort by this Column and have an outside border applied to the entire Row when there is change in value in Column H. Problem is, I'm frequenlty adding additional Rows of data so when I re-sort the data by Column H, the border doesn't move. For example, I have a border between Rows 25 and 26 because the value in H has gone from 3 to 4. However, if I add a new Row with a value of 3 in Column H and re-sort, the border stays where it is and now I have a Row with a value of 3 in the "section" of Rows with 4 in Column H (for illustration purposes, the underlined text below represents a border).

3
3
3
3
4
4
4

I'm using conditional formatting for another reason already. Attached is an example of the sheet...

I use conditional formatting to give me the color change, but I'm not seeing how to have the entire row formatted with a border at a change in value (sorry for my ignorance).

Hello efab,

It seems a working example of the code is what you want. I have added a button to the worksheet to run the macro. The data will be sorted by Team, School, and Gender in ascending order. Separating borders will then be added where the numbers change. Here is the macro code...

Sub SortAndFormat()

  Dim I As Integer
  Dim PrevNum As Integer
  Dim Rng As Range
  
    Application.ScreenUpdating = False
    Set Rng = ActiveSheet.Cells(1, 1).CurrentRegion
    
     'Sort the table by:Team, School, Gender
      Rng.Sort Key1:=Rng.Cells(1, 8), Order1:=xlAscending, _
               Key2:=Rng.Cells(1, 7), Order2:=xlAscending, _
               Key3:=Rng.Cells(1, 5), Order3:=xlAscending, _
               Header:=xlYes, Orientation:=xlSortColumns, MatchCase:=False
               
      'Format only the table data and not the header row
       Set Rng = Rng.Offset(1, 0).Resize(Rowsize:=Rng.Rows.Count - 1)
       
        'Remove the separating borders in the table
         For I = 1 To Rng.Rows.Count - 1
           With Rng.Rows(I).Borders(xlEdgeBottom)
             If .LineStyle <> xlLineStyleNone Then
                .LineStyle = xlLineStyleNone
             End If
           End With
         Next I
         
        'Add the separating borders between the nunmbers
         PrevNum = Rng.Cells(1, 8)
           For I = 1 To Rng.Rows.Count - 1
             If Rng.Cells(I, 8) <> PrevNum Then
                With Rng.Rows(I - 1).Borders(xlEdgeBottom)
                  .LineStyle = xlContinuous
                  .Weight = xlMedium
                End With
             End If
             PrevNum = Rng.Cells(I, 8)
           Next I
         
    Application.ScreenUpdating = True
    
End Sub

Sincerely,
Leith Ross