hiding sheets but still letting macros run when printing hidden sheets

You need to unhide the sheet

Application.ScreenUpdating = False
    With Worksheets("receipt of deposit letter")
        .Visible = xlSheetVisible
        .PrintOut
        .Visible = xlSheetVeryHidden
    End With
    Application.ScreenUpdating = True

Steve, does this work for you?

Sub PRINTSUPPLYONLY()
Application.ScreenUpdating = False
Select Case MsgBox("HAVE YOU SELECTED THE SYSTEM IN THE DELIVERY SHEET?", _
    vbYesNo + vbQuestion + vbDefaultButton1, "Delivery sheet")
    Case vbYes
        MsgBox "THESE ARE ALL TO BE SENT TO THE CUSTOMER " & _
            Chr(10) & "PLEASE INSERT 1 SHEET OF HEADED PAPER!"
        Sheets("Receipt of deposit letter").Visible = True
        Sheets("Receipt of deposit letter").PrintOut
        Sheets("Receipt of deposit letter").Visible = False
        Sheets("glass").Visible = True
        Sheets("glass").PrintOut
        Sheets("glass").Visible = False
        Sheets("Ggf").Visible = True
        Sheets("Ggf").PrintOut
        Sheets("Ggf").Visible = False
        Call SelectSheets
    Case vbNo
        Sheets("delivery note").Range("B16").Select
        Exit Sub
End Select

MsgBox "THESE ARE ALL FOR THE FILE!"
Sheets("Job sheet").Visible = True
Sheets("Job sheet").PrintOut
Sheets("Job sheet").Visible = False
Sheets("Receipt of deposit letter").Visible = True
Sheets("Receipt of deposit letter").PrintOut
Sheets("Receipt of deposit letter").Visible = False
Sheets("delivery note").Visible = True
Sheets("delivery note").PrintOut
Sheets("delivery note").Visible = False

MsgBox "INPUT DATA INTO BOOK"
Sheets("working sheet").Range("D1").Select
Application.ScreenUpdating = False
End Sub

hi pjoaquin
thanks for the reply
it works except for the fact that if i select no it shows the delivery note tab but doesnt mae it the active sheet
so i guess i should leave that particualr sheet visible?

what it should do is take me to sheet "delivery note" cell b16
asking me to input what system im using

steve

I would think you could just add:

Sheets("delivery note").Visible = True

immediately after the 'Case vbNo' statement. This, of course, would leave it open after the user edited the cell, so you may as well leave it visible.

you may need to restart your comp...

You can add this at the beginning:

Application.DisplayAlerts = False

and this at the end:

Application.DisplayAlerts = True

BUT- this message is probably just telling you that there's nothing to print on one or more of the worksheet(s) in question. You may want to step through the code line-by-line to see which sheets are causing this (if it matters to you).

This has tidied up the code, but you need to test it. I can't see why you are calling a macro called SElectSheets when the sheets are selected.

Option Explicit
Sub PRINTSUPPLYONLY()
    With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
        Select Case _
               MsgBox("HAVE YOU SELECTED THE SYSTEM IN THE DELIVERY SHEET?", _
                      vbYesNo Or vbQuestion Or vbDefaultButton1, "Delivery sheet")

            Case vbYes
                Sheets(Array("Delivery note", "Receipt of deposit letter", "glass", "Ggf")).Select
                MsgBox "THESE ARE ALL TO BE SENT TO THE CUSTOMER " & _
                       Chr(10) & "PLEASE INSERT 1 SHEET OF HEADED PAPER!"
                ActiveWindow.SelectedSheets.PrintOut Copies:=1
               Call SelectSheets    'what does this do?
            Case vbNo
                Sheets("Delivery note").Range("B16").Select
                Exit Sub
        End Select
        MsgBox "THESE ARE ALL FOR THE FILE!"
        Sheets(Array("Job sheet", "Receipt of deposit letter", "delivery note")).PrintOut Copies:=1
        ActiveWindow.SelectedSheets.PrintOut Copies:=1

        MsgBox "INPUT DATA INTO BOOK"

        .Goto (Sheets("working sheet").Range("D1"))
        .DisplayAlerts = True
        .ScreenUpdating = True
        End With
    End Sub

hi roy
i get an instant error if i click no and it highlights this line

Sheets("Delivery note").Range("B16").Select

the call selectsheets

is a way of checking a box that requires me to select any of 3 boxes that i may need and it prints off the selected sheet(s)

Notice the capitalization of "Delivery note". Based on other code, my guess is your worksheet name is actually "delivery note".

What is SelectSheets?

Maybe if you use GoTo

Option Explicit
Option Compare Text
Sub PRINTSUPPLYONLY()
    With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
        Select Case _
               MsgBox("HAVE YOU SELECTED THE SYSTEM IN THE DELIVERY SHEET?", _
                      vbYesNo Or vbQuestion Or vbDefaultButton1, "Delivery sheet")

            Case vbYes
                Sheets(Array("Delivery note", "Receipt of deposit letter", "glass", "Ggf")).Select
                MsgBox "THESE ARE ALL TO BE SENT TO THE CUSTOMER " & _
                       Chr(10) & "PLEASE INSERT 1 SHEET OF HEADED PAPER!"
                ActiveWindow.SelectedSheets.PrintOut Copies:=1
               Call SelectSheets    'what does this do?
            Case vbNo
                .Goto (Sheets("Delivery note").Range("B16"))
                Exit Sub
        End Select
        MsgBox "THESE ARE ALL FOR THE FILE!"
        Sheets(Array("Job sheet", "Receipt of deposit letter", "delivery note")).PrintOut Copies:=1
        ActiveWindow.SelectedSheets.PrintOut Copies:=1

        MsgBox "INPUT DATA INTO BOOK"

        .Goto (Sheets("working sheet").Range("D1"))
        .DisplayAlerts = True
        .ScreenUpdating = True
        End With
    End Sub

It should select the sheets in the array & print them.
I don't think that you have said what SelectSheets does.

select sheets brings up a pop up asking to select
odd
even
t&t

it has checkboxes that allows me to select any or all of them and then prints the checked sheets

and the error code highlights this line

Sheets(Array("Delivery note", "Receipt of deposit letter", "glass", "Ggf")).Select

select sheets is actually this code if it helps

Option Explicit

Sub SelectSheets()
    Dim i As Integer
    Dim TopPos As Integer
    Dim SheetCount As Integer
    Dim PrintDlg As DialogSheet
    Dim CurrentSheet As Worksheet
    Dim cb As CheckBox
    Application.ScreenUpdating = False

'   Check for protected workbook
    If ActiveWorkbook.ProtectStructure Then
        MsgBox "Workbook is protected.", vbCritical
        Exit Sub
    End If

'   Add a temporary dialog sheet
    Set CurrentSheet = ActiveSheet
    Set PrintDlg = ActiveWorkbook.DialogSheets.Add

    SheetCount = 0

'   Add the checkboxes

    TopPos = 40
    For i = 1 To ActiveWorkbook.Worksheets.Count
        Set CurrentSheet = ActiveWorkbook.Worksheets(i)
'       Skip empty sheets and hidden sheets
        Select Case CurrentSheet.Name
            Case "working sheet"
            Case "Job Sheet"
            Case "Receipt of deposit letter"
            Case "Completion sheet"
            Case "Delivery note"
            Case "Delivery note (2)"
            Case "glass"
            Case "Ggf"
        Case Else
        If Application.CountA(CurrentSheet.Cells) <> 0 And _
            CurrentSheet.Visible Then
            SheetCount = SheetCount + 1
            PrintDlg.CheckBoxes.Add 78, TopPos, 150, 16.5
                PrintDlg.CheckBoxes(SheetCount).Text = _
                    CurrentSheet.Name
            TopPos = TopPos + 13
        End If
        End Select
    Next i
        
'   Move the OK and Cancel buttons
    PrintDlg.Buttons.Left = 240

'   Set dialog height, width, and caption
    With PrintDlg.DialogFrame
        .Height = Application.Max _
            (68, PrintDlg.DialogFrame.Top + TopPos - 34)
        .Width = 430
        .Caption = "PLEASE SELECT THE OPERATING SHEETS FOR THE REUIRED NUMBER OF DOORS"

    End With

'   Change tab order of OK and Cancel buttons
'   so the 1st option button will have the focus
    PrintDlg.Buttons("Button 2").BringToFront
    PrintDlg.Buttons("Button 3").BringToFront

'   Display the dialog box
    CurrentSheet.Activate
    Application.ScreenUpdating = True
    If SheetCount <> 0 Then
        If PrintDlg.Show Then
            For Each cb In PrintDlg.CheckBoxes
                If cb.Value = xlOn Then
                    Worksheets(cb.Caption).Activate
                    ActiveSheet.PrintOut
'                   ActiveSheet.PrintPreview 'for debugging

                End If
            Next cb
        End If
    Else
        MsgBox "All worksheets are empty."
    End If

'   Delete temporary dialog sheet (without a warning)
    Application.DisplayAlerts = False
    PrintDlg.Delete

'   Reactivate original sheet
    CurrentSheet.Activate
End Sub

I think that macro is causing the problem. It will certainly print sheets twice.