Matching Values and Copying to A new sheet.

I have been searching through the forums for examples and haven't been able to find exactly what I am looking for.

Ok here is my issue. I need to compare the Conf # and line number on both sheet 1 and 2. So basically if the Conf # and the Line number match between page 1 and 2 then it copies the Conf #, Item Number(Sheet 1), and Detail(Sheet 2) to sheet 3 in a row. This needs to continue till the end of the Sheet 1. I have a pseudo report created with no code because I don't have a clue as to where to start.

If anyone can give me a push in the right direction I would greatly appreciate it.

This will be fairly straight-forward, but a couple of questions before I start ...
1. Conf # .. is this Order in your example?
2. Line Number ... is this Line Note?
3. Since you're only looking for (presumably) Order & Line to be the same across sheets 1 & 2, and since there are only 3 cols on each sheet with the third one being the only difference ... and since you only want the 3rd from sheet 2 ... then why can't you just take all the details from sheet 2? Let me know if the answers to any of these is "no" ... otherwise, you just need Order & Line (cols A & B) to be the same and then take the whole record from sheet 2 ...

OK - let's make our terms consistent; you have:
Sheet1 - Order, Line Note & Part Number
Sheet2 - Order, Line Note & Detail.

You want to find all records where Order & Line Note are the same across Sheets 1 & 2 and you want Order, Line Note & Part Number (which can all be taken from Sheet1) copied to Sheet3 ... Is this right? Or do you want the Detail from Sheet2 as well?

OK - here you go ...

Option Explicit
Option Base 1

Sub MatchAndPaste()
Dim strPartsSheet As String, strDetailSheet As String, strSummarySheet As String
Dim intFirstDataRow As Integer, intLastDataRow1 As Integer, intLastDataRow2 As Integer
Dim sht As Worksheet
Dim strPart As String, strDetail As String, strOrder As String
Dim intCount As Integer

Dim i As Integer, j As Integer

    'setup/intialise:
    strPartsSheet = "Sheet1"
    strDetailSheet = "Sheet2"
    strSummarySheet = "Sheet3"
    intFirstDataRow = 2
    
    intLastDataRow1 = Worksheets(strPartsSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    intLastDataRow2 = Worksheets(strDetailSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    
    For Each sht In Worksheets
        If sht.Name = strPartsSheet Or sht.Name = strDetailSheet Then
            Worksheets(sht.Name).Select
            Worksheets(sht.Name).Range("A1").Sort _
                key1:=Worksheets(sht.Name).Columns("A"), order1:=xlAscending, _
                key2:=Worksheets(sht.Name).Columns("B"), order2:=xlAscending, _
                header:=xlYes
        End If
    Next sht
    
    intCount = 0
    Worksheets(strSummarySheet).Cells.ClearContents
    
    For i = intFirstDataRow To intLastDataRow1
        For j = i To intLastDataRow2
            If Worksheets(1).Range("A" & i) = Worksheets(2).Range("A" & j) Then
                If Worksheets(1).Range("B" & i) = Worksheets(2).Range("B" & j) Then
                    strOrder = Worksheets(1).Cells(i, 1).Text
                    strPart = Worksheets(1).Cells(i, 3).Text
                    strDetail = Worksheets(2).Cells(j, 3).Text
                    intCount = intCount + 1
                    Worksheets(strSummarySheet).Range("A" & intFirstDataRow + intCount - 1).Value = strOrder
                    Worksheets(strSummarySheet).Range("B" & intFirstDataRow + intCount - 1).Value = strPart
                    Worksheets(strSummarySheet).Range("C" & intFirstDataRow + intCount - 1).Value = strDetail
                    Exit For   'assuming only 1 match is possible.
                End If
            End If
        Next j
    Next i
    With Worksheets(strSummarySheet)
        .Columns("A:C").NumberFormat = "@"
        .Columns("A:C").HorizontalAlignment = xlRight
        .Cells(1, 1).Value = "Order Number"
        .Cells(1, 2).Value = "Part Number"
        .Cells(1, 3).Value = "Detail"
        .Range("A1").Sort _
            key1:=Worksheets(3).Columns("A"), order1:=xlAscending, _
            key2:=Worksheets(3).Columns("B"), order2:=xlAscending, _
            header:=xlYes
    End With

End Sub

Ok...sorry for bugging everyone, After staring and the code for another 15mins I figured out how to get the mulitple lines. I know its possible to make it cleaner, but how would I go about I am not sure.

If possible the format I would like to see is:
Column A--------------Column B----------Column C
Order Number----------Part Number---------Detail
-----X-----------------X--------------More Detail
Order Number----------Part Number---------Detail
-----X-----------------X--------------More Detail
---- X-----------------X--------------More Detail

And so on if it is possible, otherwise I can live with it

I think if you take out the "Exit For" on line 48, that should do it (the one that says "assuming only 1 match is possible") ... That was only in there to make it more efficient. Let me know if you run into a problem So - this:

Option Explicit
Option Base 1

Sub MatchAndPaste()
Dim strPartsSheet As String, strDetailSheet As String, strSummarySheet As String
Dim intFirstDataRow As Integer, intLastDataRow1 As Integer, intLastDataRow2 As Integer
Dim sht As Worksheet
Dim strPart As String, strDetail As String, strOrder As String
Dim intCount As Integer
Dim booMatchFound As Boolean
Dim i As Integer, j As Integer

    'setup/intialise:
    strPartsSheet = "Sheet1"
    strDetailSheet = "Sheet2"
    strSummarySheet = "Sheet3"
    intFirstDataRow = 2
    
    intLastDataRow1 = Worksheets(strPartsSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    intLastDataRow2 = Worksheets(strDetailSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    
    For Each sht In Worksheets
        If sht.Name = strPartsSheet Or sht.Name = strDetailSheet Then
            Worksheets(sht.Name).Select 'selects sheet1
            Worksheets(sht.Name).Range("A1").Sort _
                key1:=Worksheets(sht.Name).Columns("A"), order1:=xlAscending, _
                key2:=Worksheets(sht.Name).Columns("B"), order2:=xlAscending, _
                header:=xlYes
        End If 'sorts pages to assending based on order.
    Next sht
    
    intCount = 0
    Worksheets(strSummarySheet).Cells.ClearContents 'Clears Page three
        
    For i = intFirstDataRow To intLastDataRow1 'Loop till end of sheet
        strOrder = Worksheets(1).Cells(i, 1).Text
        strPart = Worksheets(1).Cells(i, 3).Text
        strDetail = "NO MATCH"
        For j = 1 To intLastDataRow2
            If Worksheets(1).Range("A" & i) = Worksheets(2).Range("A" & j) Then
                If Worksheets(1).Range("B" & i) = Worksheets(2).Range("B" & j) Then
                    strDetail = Worksheets(2).Cells(j, 3).Text
                    intCount = intCount + 1
                    Worksheets(strSummarySheet).Range("A" & intFirstDataRow + intCount - 1).Value = strOrder
                    Worksheets(strSummarySheet).Range("B" & intFirstDataRow + intCount - 1).Value = strPart
                    Worksheets(strSummarySheet).Range("C" & intFirstDataRow + intCount - 1).Value = strDetail
                    booMatchFound = True
                    'Exit For     'assuming only 1 match is possible.
                End If
            End If
        Next j
        'if you get to here, you've cycled through the current record in sheet1 and attempted to
        'match it against all the records in sheet2 and found no match; in this case, need to
        'copy the Order and Part Number to the Summary sheet:
        If booMatchFound = False Then
            intCount = intCount + 1
            Worksheets(strSummarySheet).Range("A" & intFirstDataRow + intCount - 1).Value = strOrder
            Worksheets(strSummarySheet).Range("B" & intFirstDataRow + intCount - 1).Value = strPart
            Worksheets(strSummarySheet).Range("C" & intFirstDataRow + intCount - 1).Value = strDetail
        Else
            booMatchFound = False
        End If
    Next i
    
    With Worksheets(strSummarySheet)
        .Columns("A:C").NumberFormat = "@"
        .Columns("A:C").HorizontalAlignment = xlRight
        .Cells(1, 1).Value = "Order Number"
        .Cells(1, 2).Value = "Part Number"
        .Cells(1, 3).Value = "Detail"
        .Range("A1").Sort _
            key1:=Worksheets(3).Columns("A"), order1:=xlAscending, _
            key2:=Worksheets(3).Columns("B"), order2:=xlAscending, _
            header:=xlYes
    End With

End Sub

Yep - here you go: just make the first paste of the first two columns conditional on booMatchFound being false and remove the sort at the end.

Option Explicit
Option Base 1

Sub MatchAndPaste()
Dim strPartsSheet As String, strDetailSheet As String, strSummarySheet As String
Dim intFirstDataRow As Integer, intLastDataRow1 As Integer, intLastDataRow2 As Integer
Dim sht As Worksheet
Dim strPart As String, strDetail As String, strOrder As String
Dim intCount As Integer
Dim booMatchFound As Boolean
Dim i As Integer, j As Integer

    'setup/intialise:
    strPartsSheet = "Sheet1"
    strDetailSheet = "Sheet2"
    strSummarySheet = "Sheet3"
    intFirstDataRow = 2
    
    intLastDataRow1 = Worksheets(strPartsSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    intLastDataRow2 = Worksheets(strDetailSheet).Cells(intFirstDataRow, 1).CurrentRegion.Rows.Count
    
    For Each sht In Worksheets
        If sht.Name = strPartsSheet Or sht.Name = strDetailSheet Then
            Worksheets(sht.Name).Select
            Worksheets(sht.Name).Range("A1").Sort _
                key1:=Worksheets(sht.Name).Columns("A"), order1:=xlAscending, _
                key2:=Worksheets(sht.Name).Columns("B"), order2:=xlAscending, _
                header:=xlYes
        End If
    Next sht
    
    intCount = 0
    Worksheets(strSummarySheet).Cells.ClearContents
        
    For i = intFirstDataRow To intLastDataRow1
        strOrder = Worksheets(1).Cells(i, 1).Text
        strPart = Worksheets(1).Cells(i, 3).Text
        strDetail = "NO MATCH"
        For j = 1 To intLastDataRow2
            If Worksheets(1).Range("A" & i) = Worksheets(2).Range("A" & j) Then
                If Worksheets(1).Range("B" & i) = Worksheets(2).Range("B" & j) Then
                    strDetail = Worksheets(2).Cells(j, 3).Text
                    intCount = intCount + 1
                    If booMatchFound = False Then
                        Worksheets(strSummarySheet).Range("A" & intFirstDataRow + intCount - 1).Value = strOrder
                        Worksheets(strSummarySheet).Range("B" & intFirstDataRow + intCount - 1).Value = strPart
                    End If
                    Worksheets(strSummarySheet).Range("C" & intFirstDataRow + intCount - 1).Value = strDetail
                    booMatchFound = True
                End If
            End If
        Next j
        'if you get to here, you've cycled through the current record in sheet1 and attempted to
        'match it against all the records in sheet2 and found no match; in this case, need to
        'copy the Order and Part Number to the Summary sheet:
        If booMatchFound = False Then
            intCount = intCount + 1
            Worksheets(strSummarySheet).Range("A" & intFirstDataRow + intCount - 1).Value = strOrder
            Worksheets(strSummarySheet).Range("B" & intFirstDataRow + intCount - 1).Value = strPart
            Worksheets(strSummarySheet).Range("C" & intFirstDataRow + intCount - 1).Value = strDetail
        Else
            booMatchFound = False
        End If
    Next i
    
    With Worksheets(strSummarySheet)
        .Columns("A:C").NumberFormat = "@"
        .Columns("A:C").HorizontalAlignment = xlRight
        .Cells(1, 1).Value = "Order Number"
        .Cells(1, 2).Value = "Part Number"
        .Cells(1, 3).Value = "Detail"
    End With
    
End Sub