Append Cell Values To Text Files

I have over 1,000 text files on my hard drive.
I need to add a different line of text (a cell value) to the bottom of each of these text files (without opening them)...

I have the following setup in mind...

Column A
all text file names, including path:
C:\folder1\text1.txt
C:\folder1\text2.txt
C:\folder1\text3.txt
etc...

Column B
all the different values to append at the end of the "same row" text file:
this text (to append at the end of text1.txt)
some other text (to append at the end of text2.txt)
this text variation (to append at the end of text3.txt)
etc...

So my Excel 2003 sheet should look like this...

row1 - (A)C:\folder1\text1.txt - (B)this text
row2 - (A)C:\folder1\text2.txt - (B)some other text
row3 - (A)C:\folder1\text3.txt - (B)this text variation
etc...

Running the macro should do the following (row per row)
- append the cell value from column B to the text file in cell column A
- save the newly created text file in C:\folder2\ under the same file name.

I hope this makes sense.

Thanks for your help!!!

Stefan
P.S. I use Excel 2003 and I have no VBA programming skills, so..., much obliged to anyone who can help me out here!

Try this:

Sub x()
    Dim cell As Range
    Dim iFileNo As Integer
    
    For Each cell In Range("A2", Cells(Rows.Count, "A").End(xlUp))
        With cell
            If Len(Dir(.Text)) > 0 Then
                iFileNo = FreeFile()
                Open .Text For Append As #iFileNo
                Write #iFileNo, .Offset(, 1).Value
                Close #iFileNo
            End If
        End With
    Next cell
End Sub

It assumes you have a header in row 1.

Adding a Macro to a Code Module
1. Copy the code from the post
2. Press Alt+F11 to open the Visual Basic Editor (VBE)
3. From the menu bar in the VBE window, do Insert > Module
4. Paste the code in the window that opens
5. Close the VBE to return to Excel

- is it possible to add a line break before the inserted text?
P.S. It would also be nice to get rid of the quotes that automatically enclose the appended text (thanks again!)

Sub x()
    Dim cell As Range
    Dim iFileNo As Integer
    
    For Each cell In Range("A2", Cells(Rows.Count, "A").End(xlUp))
        With cell
            If Len(Dir(.Text)) > 0 Then
                iFileNo = FreeFile()
                Open .Text For Append As #iFileNo
                Print #iFileNo, vbCrLf & .Offset(, 1).Value
                Close #iFileNo
            End If
        End With
    Next cell
End Sub

- could the newly created file automatically be saved in C:\folder2\

That one I leave to you. You would need to copy the unmodified files to folder2, then open and append those files.

Hi Shg,

Thank you! Thank you! thank you so much !!!

What a nice and generous person you are!

That code works just Perfect!

Thanks again,

Stefan

You are more than welcome. Please see my PM -- I'll follow up in due course.