Selecting worksheets in a workbook based on criteria

Why do you need to Select the sheets, it is usually unnecessary in VBA?

This code will select all sheets starting with 18

Option Explicit
Option Base 0
Sub dynamicSheetSelect()
    Dim ws     As Worksheet
    Dim SheetsFound()
    ReDim SheetsFound(0)
    For Each ws In ActiveWorkbook.Sheets
        If Left(ws.Name, 2) = "18" Then
            SheetsFound(UBound(SheetsFound)) = ws.Name
            ReDim Preserve SheetsFound(UBound(SheetsFound) + 1)
        End If
    Next ws
    ReDim Preserve SheetsFound(UBound(SheetsFound) - 1)
    Sheets(SheetsFound).Select
End Sub

or maybe

Sub josnah()
Dim i As Integer, flg As Boolean
    For i = 1 To Sheets.Count
    If Sheets(i).Name Like "*18?*" Then
        If Not flg Then
            Sheets(i).Select
            flg = True
        Else
            Sheets(i).Select False
        End If
    End If
    Next

End Sub

VBA Noob

thanks both for your help...

i'll need to select the sheets first and then run another macro to format the sheets...
i may not be technically correct by doing this.
i'm not sure if i can not select the sheets first but run the other macro on sheets beginning with "18"

You can loop through the sheets something like this.

Puts the Sheet name in Range A1 and makes it bold

Sub FormatSht18()
Dim Wsht As Worksheet
For Each Wsht In Worksheets
    If Wsht.Name Like "*18?*" Then
       With Wsht.Range("A1")
             .Font.Bold = True
            .Value = Wsht.Name
        End With
    End If
Next Wsht
End Sub

VBA Noob

thanks alot VBA Noob!

That works just great now and yes faster too...