Delete all rows with the data "06 - DEAD" in column H

[nabeelmn]

Can Someone help me out with a macro.

I need a macro to delete all rows with the data "06 - DEAD" in column H

Would really appreciate if someone could help me out with this.

[VBA Noob]

Try

Sub DeleteColH()

    Columns("H:H").AutoFilter Field:=1, Criteria1:="06 - DEAD"
    Range("H1").Offset(1, 0).Resize(Cells(Rows.Count, "H").End(xlUp).Row) _
    .EntireRow.Delete
    ActiveSheet.AutoFilterMode = False
End Sub

VBA Noob

[VBA Noob]

Or Royuk likes using the below union method

Sub deleteRows()
    Dim cl     As Range
    Dim rng    As Range
    Dim R      As Long
    Dim X      As Long

    R = ActiveSheet.Cells(Rows.Count, "H").End(xlUp).Row
    For X = 1 To R
        If Not IsEmpty(Cells(X, "H")) And Cells(X, "H").Value = "06 - DEAD" Then
            If rng Is Nothing Then
                Set rng = Cells(X, "H")
            Else: Set rng = Union(rng, Cells(X, "H"))
            End If
        End If
    Next X
    rng.EntireRow.Delete
End Sub

VBA Noob

[royUK]

Hi Noob

Your code should be pretty quick so long as the data is in a filterable format.

[nabeelmn]

Thanks a lot!!!!