Select alternate rows: how??

[siddhantbatra]

I wrote the following code for a macro, to select alternate rows for the 300 rows in my worksheet:

Sub Macro1()
'
' Macro1 Macro
' Macro recorded 27-12-2007 by Siddhant Batra
'
Dim a As String

Dim b As Long

'
a = "1:1"

For b = 3 To 1000 Step 2

a = a & "," & Str(b) & ":" & Str(b)
Next b
 
Range(a).Select

    
End Sub

-------------

But it gives me the error "Run time error 1004: Method 'Range' of object '_Global' failed"

Please help, you must have made out that I'm an amateur

[VBA Noob]

I can select around 100 alternative rows with

Sub SelectAltRows()
Dim c As Range
Dim Str As String
     For Each c In Range("A3:A120")
          If Application.WorksheetFunction.Odd(c.Row) = c.Row Then
          Str = Str & "," & c.Address(rowabsolute = True, columnabsolute = True)
          End If
     Next c
  Str = Mid(Str, 2, Len(Str) - 1)
Range(Str).EntireRow.Select
End Sub

However you may not need to select the rows. Can you explain what you need to do with the rows

VBA Noob

[royUK]

As Noob says it is rare in VBA to need to Select a Range.

Try this code

'---------------------------------------------------------------------------------------
' Module    : Module1
' DateTime  : 09/05/2007 08:43
' Author    : Roy Cox (royUK)
' Website   : www.excel-it.com for more examples and Excel Consulting
' Purpose   : Select alternate Rows in the active sheet's used range
'             Allows for Header Row in Row 1, change
'             For X = R To 2 Step -2 to
'             For X = R To 1 Step -2 if no Header Row
' Disclaimer; This code is offered as is with no guarantees. You may use it in your
'             projects but please leave this header intact.

'---------------------------------------------------------------------------------------
Option Explicit

Sub X()
    Dim rng    As Range
    Dim R      As Long
    Dim X      As Long

    R = ActiveSheet.UsedRange.Rows.Count
    For X = R To 1 Step -2
        If rng Is Nothing Then
            Set rng = Cells(X, 1).EntireRow
        Else
            Set rng = Union(rng, Cells(X, 1).EntireRow)
        End If
    Next X
    rng.Select

End Sub