Deleting Repeated Data

I am in need of some way to delete repeating values when they are entered into excel.

Example.

Column A
Row1 12
Row2 13
Row3 12

I need row 3 to be automaticaly deleted (the whole row.) what I am doing is importing data from another workbook, but that data will contain previouse information that has already been imported and I need to delete that previouse information after I past in the data. Is there a way that Excel will search for the recuranse and delete the row where it happens.

Thank you.

Try:

Sub FixDuplicateRows() 'deletes Duplicate row
Dim RowNdx As Long
Dim ColNum As Integer
ColNum = Selection(1).Column
For RowNdx = Selection(Selection.Cells.Count).Row To _ 
        Selection(1).Row + 1 Step -1
    If Cells(RowNdx, ColNum).Value = Cells(RowNdx - 1, ColNum).Value Then
        Rows(RowNdx & ":" & RowNdx).select
        Selection.Delete
    End If
Next RowNdx
End Sub

Got this from C Pearson (http://www.cpearson.com/excel/duplicat.htm)website and adapted it to suit yours. Might not be what your looking for though!

HTH,
mccreaso

Just came across this:

Public Sub DeleteDuplicateRows()
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' DeleteDuplicateRows
' This will delete duplicate records, based on the Active Column. That is, 
' if the same value is found more than once in the Active Column, all but 
' the first (lowest row number) will be deleted.
'
' To run the macro, select the entire column you wish to scan for 
' duplicates, and run this procedure.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim R As Long
Dim N As Long
Dim V As Variant
Dim Rng As Range

On Error GoTo EndMacro
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual


Set Rng = Application.Intersect(ActiveSheet.UsedRange, _ 
                    ActiveSheet.Columns(ActiveCell.Column))

Application.StatusBar = "Processing Row: " & Format(Rng.Row, "#,##0")

N = 0
For R = Rng.Rows.Count To 2 Step -1
If R Mod 500 = 0 Then
    Application.StatusBar = "Processing Row: " & Format(R, "#,##0")
End If

V = Rng.Cells(R, 1).Value
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Note that COUNTIF works oddly with a Variant that is equal to vbNullString.
' Rather than pass in the variant, you need to pass in vbNullString explicitly.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
If V = vbNullString Then
    If Application.WorksheetFunction.CountIf(Rng.Columns(1), vbNullString) > 1 Then
        Rng.Rows(R).EntireRow.Delete
        N = N + 1
    End If
Else
    If Application.WorksheetFunction.CountIf(Rng.Columns(1), V) > 1 Then
        Rng.Rows(R).EntireRow.Delete
        N = N + 1
    End If
End If
Next R

EndMacro:

Application.StatusBar = False
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
MsgBox "Duplicate Rows Deleted: " & CStr(N)

End Sub

@ http://www.cpearson.com/excel/deleting.htm , exactly what your looking for?

mccreaso

MCCREASO!! That is exactly what I needed thank you!