Very Difficult & Detailed Macro to find Duplicates

I work with large spreadsheets. I was hoping that someone would know how to create a macro that will take selected cells in column C and search all of column C for exact duplicate entries. The macro envisioned would let you select cells to test. If a dulicate entry is found I would need the macro to test the cells in column E against one another. If both C & E match exact (if possible maybe display the findings in a pop up box) I would like the macro to ask me if I want to delete the duplicate entry, if yes, delete the entire row. If no, skip it and move to the next one. If C but not E match I would need the macro to ask me if I want to remove thetest cell. if yes, cut out the entire row of the TEST cell and paste it in a new sheet. If no skip it and move on.
Am I just dreaming or can this be done. If it can be done, but more info is needed let me know.
I thank you very much for your time and help and effort.

it can be done

it would make it easier if you could paste an example of your workbook

In this example there are some duplicates for C only and some for both C&E. I would be without words if a macro could be built as described in my 1st post.

Try this macro
I beleive it does everyting you asked for

Sub FindDuplicates()
   Dim Rng As Range
   Dim rFound As Range
   Dim rFrom
   
   Dim sFind As String
   Dim sMB As String
   Dim wS As Worksheet
   
   Set wS = ActiveSheet
   For Each Rng In Selection
      If Rng.Column = 3 Then
         Set rFrom = Rng
         Do
            Set rFound = wS.Columns("c").Find(What:=Rng.Value, _
               After:=rFrom, LookIn:=xlFormulas, _
               LookAt:=xlWhole, SearchOrder:=xlByRows, _
               SearchDirection:=xlNext, _
               MatchCase:=False, SearchFormat:=False)
         
            If Not rFound Is Nothing Then
               If rFound.Row = Rng.Row Then
                  Exit Do
               End If
               If rFound.Address <> Rng.Address Then
                  If rFound.Offset(0, 2).Value = Rng.Offset(0, 2).Value Then
                     sMB = MsgBox("Duplicates Found Rows " & rFound.Row & " & " & Rng.Row _
                        & Chr(10) & Chr(10) _
                        & "Delete Duplicate from Row " & rFound.Row, _
                        vbYesNo + vbQuestion)
                     If sMB = vbYes Then
                        wS.Rows(rFound.Row).Delete
                        Set rFrom = Rng
                     Else
                        Set rFrom = rFound
                     End If
                  Else
                     sMB = MsgBox("Duplicates Found Rows " & rFound.Row & " & " & Rng.Row _
                        & Chr(10) _
                        & "With Non Matching Column E Entries" _
                        & Chr(10) _
                        & "Remove Row " & rFound.Row & " Entry", _
                        vbYesNo + vbQuestion)
                     If sMB = vbYes Then
                        Sheets.Add
                        wS.Rows(rFound.Row).Copy
                        ActiveSheet.Paste
                        wS.Rows(rFound.Row).Delete
                        Set rFrom = Rng
                     Else
                        Set rFrom = rFound
                     End If
                  End If
               End If
            End If
         Loop
      End If
   Next Rng
   CreateObject("WScript.Shell").Popup "Process Finished", 2, _
      "This Message Self Destructs in 2 seconds "
End Sub